reserve i,j,n,k,m for Nat,
     a,b,x,y,z for object,
     F,G for FinSequence-yielding FinSequence,
     f,g,p,q for FinSequence,
     X,Y for set,
     D for non empty set;
reserve
  B,A,M for BinOp of D,
  F,G for D* -valued FinSequence,
  f for FinSequence of D,
  d,d1,d2 for Element of D;
reserve
  F,G for non-empty non empty FinSequence of D*,
  f for non empty FinSequence of D;
reserve f,g for FinSequence of D,
        a,b,c for set,
        F,F1,F2 for finite set;

theorem Th111:
  for E be Enumeration of F, p be Permutation of dom E
    for s be FinSequence st s in doms (SignGenOp(f,A,F) * E) holds
     ((App (SignGenOp(f,A,F) * E)).s)*p =
        ((App (SignGenOp(f,A,F) * (E*p))).(s*p))
proof
  let E be Enumeration of F, p be Permutation of dom E;
  set C=SignGenOp(f,A,F);
  let s be FinSequence such that
A1: s in doms (C * E);
A2: s*p in doms (C * (E * p)) by A1,Th110;
  then reconsider sp=s*p as FinSequence;
A3: len s = len (C * E) = len E by Th47,A1,CARD_1:def 7;
  then
A4: dom E = dom (C*E) = dom s by FINSEQ_3:30;
A5: dom p = dom E = rng p by FUNCT_2:52,def 3;
  then
A6: dom sp = dom s by A4,RELAT_1:27;
A7: len ((App (C * (E*p))).sp) = len sp by A2,Def9;
  then
A8: dom ((App (C * (E*p))).sp) = dom sp by FINSEQ_3:29;
  len ((App (C * E)).s) = len s by A1,Def9;
  then
A9: dom ((App (C * E)).s) = dom s by FINSEQ_3:29;
  then
A10: dom (((App (C * E)).s)*p) = dom p by A5,A3,FINSEQ_3:30,RELAT_1:27;
  for i st i in dom ((App (C * (E*p))).sp) holds
    (((App (C * E)).s)*p).i = ((App (C * (E*p))).sp).i
  proof
    let i such that A11: i in dom ((App (C * (E*p))).sp);
    i in dom sp by A7,FINSEQ_3:29,A11;
    then
A12: ((App (C * (E*p))).sp).i = (C * (E*p)).i.(sp.i) & sp.i =s.(p.i)
      by A2,Def9,FUNCT_1:12;
A13: i in dom p & p.i in dom s by A11,A8,FUNCT_1:11;
    (((App (C * E)).s)*p).i = ((App (C * E)).s).(p.i) &
      i in dom p & p.i in dom ((App (C * E)).s)
      by A5,A4,A11,A8,A10,A6,FUNCT_1:11,12;
    then
A14:  (((App (C * E)).s)*p).i = ((C*E)).(p.i).(sp.i) by A1,Def9,A9,A12;
    ((C * E)).(p.i) = ((C*E)*p).i by A13,FUNCT_1:13;
    hence thesis by RELAT_1:36,A12,A14;
  end;
  hence thesis by A8,A10,A4,FUNCT_2:52,A6;
end;
