reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem
  for f be PartFunc of RNS,CNS st f is_Lipschitzian_on X holds -f
  is_Lipschitzian_on X & ||.f.|| is_Lipschitzian_on X
proof
  let f be PartFunc of RNS,CNS;
  assume
A1: f is_Lipschitzian_on X;
  then consider s be Real such that
A2: 0 < s and
A3: for x1,x2 be Point of RNS st x1 in X & x2 in X holds ||. f/.x1-f/.x2
  .||<=s*||. x1-x2.||;
  -f = (-1r)(#)f by VFUNCT_2:23;
  hence -f is_Lipschitzian_on X by A1,Th108;
  X c= dom f by A1;
  hence
A4: X c= dom (||.f.|| ) by NORMSP_0:def 3;
  take s;
  thus 0<s by A2;
  let x1,x2 be Point of RNS;
  assume that
A5: x1 in X and
A6: x2 in X;
  |. (||.f.|| )/.x1-(||.f.|| )/.x2 .| = |. (||.f.|| ).x1-(||.f.|| )/.x2
  .| by A4,A5,PARTFUN1:def 6
  .= |. (||.f.|| ).x1-(||.f.|| ).x2 .| by A4,A6,PARTFUN1:def 6
    .= |. ||. f/.x1.||-(||.f.|| ).x2 .| by A4,A5,NORMSP_0:def 3
    .= |.||. f/.x1.|| - ||. f/.x2 .||.| by A4,A6,NORMSP_0:def 3;
  then
A7: |. (||.f.|| )/.x1-(||.f.|| )/.x2 .| <= ||. f/.x1-f/.x2.|| by CLVECT_1:110;
  ||. f/.x1-f/.x2 .|| <= s*||. x1-x2.|| by A3,A5,A6;
  hence thesis by A7,XXREAL_0:2;
end;
