reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;
reserve y for set,
  H19,H29 for StableSubgroup of G,
  N19 for normal StableSubgroup of H19,
  s1,s19,s2,s29 for CompositionSeries of G,
  fs for FinSequence of the_stable_subgroups_of G,
  f1,f2 for FinSequence,
  i,j,n for Nat;

theorem Th113:
  s1 is_equivalent_with s1
proof
  per cases;
  suppose
    s1 is empty;
    hence thesis;
  end;
  suppose
A1: s1 is not empty;
    set f1=the_series_of_quotients_of s1;
    now
      set p = id dom f1;
      reconsider p as Function of dom f1,dom f1;
      p is onto;
      then reconsider p as Permutation of dom f1;
      take p;
A2:   now
        let H1,H2 be GroupWithOperators of O;
        let i,j;
        assume
A3:     i in dom f1 & j=p".i;
A4:     p" = p by FUNCT_1:45;
        assume H1=f1.i & H2=f1.j;
        hence H1,H2 are_isomorphic by A3,A4,FUNCT_1:18;
      end;
      thus f1,f1 are_equivalent_under p,O by A2;
    end;
    hence thesis by A1,Th108;
  end;
end;
