reserve            S for satisfying_CongruenceSymmetry
                         satisfying_CongruenceEquivalenceRelation
                         TarskiGeometryStruct,
         a,b,c,d,e,f for POINT of S;
reserve S for satisfying_CongruenceSymmetry
              satisfying_CongruenceEquivalenceRelation
              satisfying_CongruenceIdentity
              satisfying_SegmentConstruction
              satisfying_SAS
              TarskiGeometryStruct,
        q,a,b,c,a9,b9,c9,x1,x2 for POINT of S;
reserve S for satisfying_CongruenceIdentity
              satisfying_SegmentConstruction
              satisfying_BetweennessIdentity
              satisfying_Pasch
              TarskiGeometryStruct,
        a,b,c,d for POINT of S;
reserve       S for satisfying_Tarski-model TarskiGeometryStruct,
        a,b,c,d for POINT of S;
reserve         S for satisfying_CongruenceIdentity
                      satisfying_SegmentConstruction
                      satisfying_BetweennessIdentity
                      satisfying_Pasch
                      TarskiGeometryStruct,
        a,b,c,d,e for POINT of S;
reserve       S for satisfying_Tarski-model
                    TarskiGeometryStruct,
      a,b,c,d,p for POINT of S;
reserve                   S for satisfying_Tarski-model TarskiGeometryStruct,
        a,b,c,d,a9,b9,c9,d9 for POINT of S;
reserve S for satisfying_Tarski-model
              TarskiGeometryStruct,
        a,b,c,d,a9,b9,c9,d9,p,q for POINT of S;
reserve                       S for satisfying_Tarski-model
                                    TarskiGeometryStruct,
        a,b,c,d,e,f,a9,b9,c9,d9 for POINT of S;
reserve p for POINT of S;
reserve r for POINT of S;
reserve x,y for POINT of S;
reserve S for non empty satisfying_Tarski-model TarskiGeometryStruct;
reserve p,q,r,s for POINT of S;
reserve S for non empty satisfying_CongruenceIdentity
              satisfying_SegmentConstruction
              satisfying_BetweennessIdentity
              satisfying_Pasch
              TarskiGeometryStruct,
  a,b,p,q for POINT of S;
reserve S for non empty satisfying_Tarski-model TarskiGeometryStruct,
                  A,B for Subset of S,
        a,b,c,p,q,r,s for POINT of S;
reserve S for satisfying_CongruenceIdentity
              satisfying_CongruenceSymmetry
              satisfying_CongruenceEquivalenceRelation
              satisfying_SegmentConstruction
              satisfying_BetweennessIdentity
              satisfying_Pasch
              TarskiGeometryStruct,
        a,b,m for POINT of S;
reserve S for satisfying_CongruenceIdentity
              satisfying_CongruenceSymmetry
              satisfying_CongruenceEquivalenceRelation
              satisfying_SegmentConstruction
              satisfying_BetweennessIdentity
              TarskiGeometryStruct,
        a,b,m for POINT of S;
reserve S for satisfying_CongruenceIdentity
              satisfying_CongruenceSymmetry
              satisfying_CongruenceEquivalenceRelation
              satisfying_SegmentConstruction
              satisfying_SAS
              TarskiGeometryStruct,
        a for POINT of S;
reserve S for satisfying_CongruenceIdentity
              satisfying_CongruenceSymmetry
              satisfying_CongruenceEquivalenceRelation
              satisfying_SegmentConstruction
              satisfying_BetweennessIdentity
              satisfying_SAS
              TarskiGeometryStruct,
  a,p,p9 for POINT of S;
reserve S for satisfying_CongruenceIdentity
              satisfying_CongruenceSymmetry
              satisfying_CongruenceEquivalenceRelation
              satisfying_SegmentConstruction
              satisfying_BetweennessIdentity
              satisfying_SAS
              satisfying_Pasch
              TarskiGeometryStruct,
  a,p,p9 for POINT of S;
reserve S for satisfying_CongruenceIdentity
                satisfying_CongruenceSymmetry
                satisfying_CongruenceEquivalenceRelation
                satisfying_SegmentConstruction
                satisfying_BetweennessIdentity
                satisfying_SAS
                TarskiGeometryStruct,
        a,p for POINT of S;
reserve              S for satisfying_Tarski-model TarskiGeometryStruct,
        a,b,c,d,m,p,p9,q,r,s for POINT of S;
reserve         S for non empty satisfying_Tarski-model TarskiGeometryStruct,
        a,b,c,d,p for POINT of S;
reserve a1,a2,b1,b2,m1,m2 for POINT of S;

theorem Satz7p22part1:
  between a1,c,a2 & between b1,c,b2 & c,a1 equiv c,b1 &
  c,a2 equiv c,b2 & Middle a1,m1,b1 & Middle a2,m2,b2 &
  c,a1 <= c,a2
  implies between m1,c,m2
  proof
    assume that
A1: between a1,c,a2 and
A2: between b1,c,b2 and
A3: c,a1 equiv c,b1 and
A4: c,a2 equiv c,b2 and
A5: Middle a1,m1,b1 and
A6: Middle a2,m2,b2 and
A7: c,a1 <= c,a2;
    per cases;
    suppose
A8:   a2 = c;
      a1 = c
      proof
        consider x be POINT of S such that
A9:     between c,a1,x and
A10:    c,x equiv c,c by A7,A8,Satz5p5;
        c = x by A10,GTARSKI1:def 7;
        hence thesis by A9,GTARSKI1:def 10;
      end;
      then Middle a1,m1,a1 & Middle a2,m2,a2
        by A5,A6,A8,A3,A4,Satz2p2,GTARSKI1:def 7;
      then m1 = a1 & m2 = a2 by GTARSKI1:def 10;
      hence thesis by A8,Satz3p1;
    end;
    suppose
A11:  a2 <> c;
      set a = reflection(c,a2),
          b = reflection(c,b2),
          m = reflection(c,m2);
      now
        thus c,a1 equiv c,a1 by Satz2p1;
        c,a2 equiv reflection(c,c),reflection(c,a2) by Satz7p13;
        hence c,a2 equiv c,a by Satz7p10;
      end;
      then
A12:  c,a1 <= c,a by A7,Satz5p6;
      per cases;
      suppose
A13:    a1 = c;
        then a1 = b1 by A3,Satz2p2,GTARSKI1:def 7;
        then m1 = a1 by A5,GTARSKI1:def 10;
        hence thesis by A13,Satz3p1,Satz3p2;
      end;
      suppose
A14:    a1 <> c;
A15:    between c,a1,a
        proof
          c out a1,a
          proof
            now
              thus c <> a1 by A14;
              thus c <> a
              proof
                assume c = a;
                then reflection(c,a2) = reflection(c,c) by Satz7p10;
                hence contradiction by A11,Satz7p9;
              end;
              thus between c,a1,a or between c,a,a1
              proof
A16:            Middle a2,c,a by DEFR;
A17:            between a2,c,a1 by A1,Satz3p2;
                then per cases by A11,A16,Satz5p1;
                suppose between a2,a,a1;
                  hence thesis by A16,Satz3p6p1;
                end;
                suppose between a2,a1,a;
                  hence thesis by A17,Satz3p6p1;
                end;
              end;
            end;
            hence thesis;
          end;
          hence thesis by A12,Satz6p13;
        end;
A18:    between c,b1,b
        proof
          per cases;
          suppose c = b1;
            hence thesis by A14,A3,GTARSKI1:def 7;
          end;
          suppose
A19:        c <> b1;
A20:        c,b1 <= c,b2 by A3,A4,A7,Satz5p6;
            c,b2 equiv reflection(c,c),reflection(c,b2) by Satz7p13;
            then c,b2 equiv c,b & c,b1 equiv c,b1 by Satz2p1,Satz7p10;
            then
A21:        c,b1 <= c,b by A20,Satz5p6;
A22:        b2 <> c by A11,A4,GTARSKI1:def 7;
            c out b1,b
            proof
              now
                thus c <> b1 by A19;
                thus c <> b
                proof
                  assume c = b;
                  then reflection(c,b2) = reflection(c,c) by Satz7p10;
                  hence contradiction by A22,Satz7p9;
                end;
                thus between c,b1,b or between c,b,b1
                proof
A23:              Middle b2,c,b by DEFR;
A24:              between b2,c,b1 by A2,Satz3p2;
                  then between b2,b,b1 or between b2,b1,b by A22,A23,Satz5p1;
                  hence thesis by A23,A24,Satz3p6p1;
                end;
              end;
              hence thesis;
            end;
            hence thesis by A21,Satz6p13;
          end;
        end;
        between a,a1,c & between b,b1,c &
          between a,m,b by A18,Satz3p2,A15,A6,Satz7p15;
        then consider q be POINT of S such that
A25:    between m,q,c and
A26:    between a1,q,b1 by Satz3p17;
A27:    between m,c,m2
        proof
          Middle m2,c,m by DEFR;
          hence thesis by Satz3p2;
        end;
        q = m1
        proof
          a,a1,c,m IFS b,b1,c,m
          proof
            now
              thus between a,a1,c by A15,Satz3p2;
              thus between b,b1,c by A18,Satz3p2;
              reflection(c,c),reflection(c,a2) equiv
                reflection(c,c),reflection(c,b2) by A4,Satz7p16;
              then c,reflection(c,a2) equiv reflection(c,c),reflection(c,b2)
                by Satz7p10;
              then c,a equiv c,b by Satz7p10;
              then c,a equiv b,c by Satz2p5;
              hence a,c equiv b,c by Satz2p4;
              c,a1 equiv b1,c by A3,Satz2p5;
              hence a1,c equiv b1,c by Satz2p4;
              m2,a2 equiv b2,m2 by A6,Satz2p5;
              then a2,m2 equiv b2,m2 by Satz2p4;
              hence a,m equiv b,m by Satz7p16;
              thus c,m equiv c,m by Satz2p1;
            end;
            hence thesis;
          end;
          then a1,m equiv b1,m by Satz4p2; then
A28:      a1,m equiv m,b1 by Satz2p5; then
A29:      m,a1 equiv m,b1 by Satz2p4;
          q,a1 equiv q,b1
          proof
            per cases;
            suppose
A30:          m <> c;
              Collinear c,m,q by A25;
              hence thesis by A3,A29,A30,Satz4p17;
            end;
            suppose m = c;
              then q = m by A25,GTARSKI1:def 10;
              hence thesis by A28,Satz2p4;
            end;
          end;
          then Middle a1,q,b1 by A26;
          hence thesis by A5,Satz7p17;
        end;
        hence thesis by A27,A25,Satz3p6p1;
      end;
    end;
  end;
