reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;
reserve y for set,
  H19,H29 for StableSubgroup of G,
  N19 for normal StableSubgroup of H19,
  s1,s19,s2,s29 for CompositionSeries of G,
  fs for FinSequence of the_stable_subgroups_of G,
  f1,f2 for FinSequence,
  i,j,n for Nat;

theorem Th114:
  (len s1<=1 or len s2<=1) & len s1<=len s2 implies s2 is_finer_than s1
proof
  assume
A1: len s1<=1 or len s2<=1;
  assume
A2: len s1<=len s2;
  then
A3: len s1 <=1 by A1,XXREAL_0:2;
  per cases;
  suppose
A4: len s1=1;
    then
A5: s1 = <* s1.1 *> by FINSEQ_1:40;
    now
      reconsider D=Seg len s2 as non empty set by A2,A4;
      set x={1};
      take x;
      set f=s2;
      set p=<*1*>;
      dom f = Seg len s2 & rng f c= the_stable_subgroups_of G by FINSEQ_1:def 3
;
      then reconsider f as Function of D, the_stable_subgroups_of G by
FUNCT_2:2;
A6:   1 in Seg len s2 by A2,A4;
      then 1 in dom s2 by FINSEQ_1:def 3;
      hence x c= dom s2 by ZFMISC_1:31;
      {1} c= D by A6,ZFMISC_1:31;
      then rng p c= D by FINSEQ_1:38;
      then reconsider p as FinSequence of D by FINSEQ_1:def 4;
      Sgm x = p & f * p = <* f.1 *> by FINSEQ_2:35,FINSEQ_3:44;
      then s2 * Sgm x = <* (Omega).G *> by Def28;
      hence s1 = s2 * Sgm x by A5,Def28;
    end;
    hence thesis;
  end;
  suppose
    len s1<>1;
    then len s1<0+1 by A3,XXREAL_0:1;
    then
A7: s1={} by NAT_1:13;
    now
      set x={};
      take x;
      thus x c= dom s2;
      thus s1 = s2 * Sgm x by A7,FINSEQ_3:43;
    end;
    hence thesis;
  end;
end;
