reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem Th117:
  for f be PartFunc of CNS,RNS st f is_Lipschitzian_on X holds f
  is_continuous_on X
proof
  let f be PartFunc of CNS,RNS;
  assume
A1: f is_Lipschitzian_on X;
  then consider r be Real such that
A2: 0 < r and
A3: for x1,x2 be Point of CNS st x1 in X & x2 in X holds ||. f/.x1-f/.x2
  .||<=r*||. x1-x2.||;
A4: X c= dom f by A1;
  then
A5: dom (f|X) = X by RELAT_1:62;
  now
    let x0 be Point of CNS such that
A6: x0 in X;
    now
      let g be Real such that
A7:   0<g;
       reconsider s=g/r as Real;
      take s9=s;
A8:   now
        let x1 be Point of CNS;
        assume that
A9:     x1 in dom (f|X) and
A10:    ||. x1- x0 .|| <s;
        r*||. x1- x0 .|| <(g/r)*r by A2,A10,XREAL_1:68;
        then
A11:    r*||. x1- x0 .|| <g by A2,XCMPLX_1:87;
        ||. f/.x1- f/.x0 .|| <=r*||. x1- x0 .|| by A3,A5,A6,A9;
        then ||. f/.x1- f/.x0 .|| <g by A11,XXREAL_0:2;
        then ||. (f|X)/.x1-f/.x0 .||<g by A9,PARTFUN2:15;
        hence ||. (f|X)/.x1-(f|X)/.x0 .||<g by A5,A6,PARTFUN2:15;
      end;
      0<r" & s9=g*r" by A2,XCMPLX_0:def 9;
      hence
      0<s9 & for x1 be Point of CNS st x1 in dom (f|X) & ||. x1- x0 .|| <
      s9 holds ||. (f|X)/.x1-(f|X)/.x0.||<g by A7,A8,XREAL_1:129;
    end;
    hence f|X is_continuous_in x0 by A5,A6,Th9;
  end;
  hence thesis by A4;
end;
