reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th118:
  for cn being Real,K1 being non empty Subset of TOP-REAL 2, f
being Function of (TOP-REAL 2)|K1,R^1 st cn<1 & (for p being Point of (TOP-REAL
2) st p in the carrier of (TOP-REAL 2)|K1 holds f.p=|.p.|*( -sqrt(1-((p`1/|.p.|
  -cn)/(1-cn))^2))) & (for q being Point of TOP-REAL 2 st q in the carrier of (
  TOP-REAL 2)|K1 holds q`2<=0 & q`1/|.q.|>=cn & q<>0.TOP-REAL 2) holds f is
  continuous
proof
  let cn be Real,K1 be non empty Subset of TOP-REAL 2,
f be Function of (
  TOP-REAL 2)|K1,R^1;
  reconsider g1=(2 NormF)|K1 as continuous Function of (TOP-REAL 2)|K1,R^1 by
Lm5;
  set a=cn, b=1-cn;
  reconsider g2=proj1|K1 as continuous Function of (TOP-REAL 2)|K1,R^1 by Lm2;
  assume that
A1: cn<1 and
A2: for p being Point of (TOP-REAL 2) st p in the carrier of (TOP-REAL 2
  )|K1 holds f.p=|.p.|*( -sqrt(1-((p`1/|.p.|-cn)/(1-cn))^2)) and
A3: for q being Point of TOP-REAL 2 st q in the carrier of (TOP-REAL 2)
  |K1 holds q`2<=0 & q`1/|.q.|>=cn & q<>0.TOP-REAL 2;
  for q being Point of TOP-REAL 2 st q in the carrier of (TOP-REAL 2)|K1
  holds q<>0.TOP-REAL 2 by A3;
  then
A4: for q being Point of (TOP-REAL 2)|K1 holds g1.q<>0 by Lm6;
  b>0 by A1,XREAL_1:149;
  then consider g3 being Function of (TOP-REAL 2)|K1,R^1 such that
A5: for q being Point of (TOP-REAL 2)|K1,r1,r2 being Real st g2.q
  =r1 & g1.q=r2 holds g3.q=r2*( -sqrt(|.1-((r1/r2-a)/b)^2.|)) and
A6: g3 is continuous by A4,Th9;
A7: dom g3=the carrier of (TOP-REAL 2)|K1 by FUNCT_2:def 1;
  then
A8: dom f=dom g3 by FUNCT_2:def 1;
  for x being object st x in dom f holds f.x=g3.x
  proof
    let x be object;
A9: 1-cn>0 by A1,XREAL_1:149;
    assume
A10: x in dom f;
    then x in K1 by A7,A8,PRE_TOPC:8;
    then reconsider r=x as Point of (TOP-REAL 2);
A11: |.r.|<>0 by A3,A10,TOPRNS_1:24;
    |.r.|^2=(r`1)^2+(r`2)^2 by JGRAPH_3:1;
    then
A12: ((r`1) -(|.r.|))*((r`1)+|.r.|) =-(r`2)^2;
    (r`2)^2>=0 by XREAL_1:63;
    then r`1<= |.r.| by A12,XREAL_1:93;
    then r`1/|.r.| <= |.r.|/|.r.| by XREAL_1:72;
    then r`1/|.r.|<=1 by A11,XCMPLX_1:60;
    then
A13: r`1/|.r.|-cn<=(1-cn) by XREAL_1:9;
    reconsider s=x as Point of (TOP-REAL 2)|K1 by A10;
A14: now
      assume (1-cn)^2=0;
      then 1-cn+cn=0+cn by XCMPLX_1:6;
      hence contradiction by A1;
    end;
    cn-r`1/|.r.|<=0 by A3,A10,XREAL_1:47;
    then -(cn- r`1/|.r.|)>=-(1-cn) by A9,XREAL_1:24;
    then (1-cn)^2>=0 & (r`1/|.r.|-cn)^2<=(1-cn)^2 by A13,SQUARE_1:49,XREAL_1:63
;
    then (r`1/|.r.|-cn)^2/(1-cn)^2<=(1-cn)^2/(1-cn)^2 by XREAL_1:72;
    then (r`1/|.r.|-cn)^2/(1-cn)^2<=1 by A14,XCMPLX_1:60;
    then ((r`1/|.r.|-cn)/(1-cn))^2<=1 by XCMPLX_1:76;
    then 1-((r`1/|.r.|-cn)/(1-cn))^2>=0 by XREAL_1:48;
    then |.1-((r`1/|.r.|-cn)/(1-cn))^2.| =1-((r`1/|.r.|-cn)/(1-cn))^2 by
ABSVALUE:def 1;
    then
A15: f.r=(|.r.|)*(-sqrt(|.1-((r`1/|.r.|-cn)/(1-cn))^2.|)) by A2,A10;
A16: proj1.r=r`1 & (2 NormF).r=|.r.| by Def1,PSCOMP_1:def 5;
    g2.s=proj1.s & g1.s=(2 NormF).s by Lm2,Lm5;
    hence thesis by A5,A15,A16;
  end;
  hence thesis by A6,A8,FUNCT_1:2;
end;
