reserve x,x0, r,r1,r2 for Real,
      th for Real,

  rr for set,

  rseq for Real_Sequence;

theorem
  -sqrt 2 < r & r < -1 implies cosec.(arcsec2 r) = -r/sqrt(r^2-1)
proof
  set x = arcsec2 r;
A1: ].3/4*PI,PI.[ c= dom cosec
  proof
    ].3/4*PI,PI.[ /\ sin"{0} = {}
    proof
      assume ].3/4*PI,PI.[ /\ sin"{0} <> {};
      then consider rr being object such that
A2:   rr in ].3/4*PI,PI.[ /\ sin"{0} by XBOOLE_0:def 1;
      rr in sin"{0} by A2,XBOOLE_0:def 4;
      then
A3:   sin.rr in {0} by FUNCT_1:def 7;
A4:   ].3/4*PI,PI.[ c= ].0,PI.[ by XXREAL_1:46;
      rr in ].3/4*PI,PI.[ by A2,XBOOLE_0:def 4;
      then sin.rr <> 0 by A4,COMPTRIG:7;
      hence contradiction by A3,TARSKI:def 1;
    end;
    then ].3/4*PI,PI.[ \ sin"{0} c= dom sin \ sin"{0} & ].3/4*PI,PI.[ misses
    sin"{0} by SIN_COS:24,XBOOLE_0:def 7,XBOOLE_1:33;
    then ].3/4*PI,PI.[ c= dom sin \ sin"{0} by XBOOLE_1:83;
    hence thesis by RFUNCT_1:def 2;
  end;
  assume
A5: -sqrt 2 < r & r < -1;
  then 3/4*PI < arcsec2 r & arcsec2 r < PI by Th110;
  then x in ].3/4*PI,PI.[;
  then cosec.x = 1/sin.x by A1,RFUNCT_1:def 2
    .= 1/(-sqrt(r^2-1)/r) by A5,Th114
    .= -1/(sqrt(r^2-1)/r) by XCMPLX_1:188
    .= -r/sqrt(r^2-1) by XCMPLX_1:57;
  hence thesis;
end;
