reserve x,y,y1,y2 for set;
reserve G for Group;
reserve a,b,c,d,g,h for Element of G;
reserve A,B,C,D for Subset of G;
reserve H,H1,H2,H3 for Subgroup of G;
reserve n for Nat;
reserve i for Integer;
reserve L for Subset of Subgroups G;
reserve N2 for normal Subgroup of G;

theorem Th119:
  for H being Subgroup of G holds H is normal Subgroup of G iff
  for a holds H * a c= a * H
proof
  let H be Subgroup of G;
  thus H is normal Subgroup of G implies for a holds H * a c= a * H by Th117;
  assume
A1: for a holds H * a c= a * H;
  now
    let a;
    H * a" c= a" * H by A1;
    then a * (H * a") c= a * (a" * H) by Th4;
    then a * (H * a") c= a * a" * H by GROUP_2:105;
    then a * (H * a") c= 1_G * H by GROUP_1:def 5;
    then a * (H * a") c= carr H by GROUP_2:109;
    then a * H * a" c= carr H by GROUP_2:106;
    then a * H * a" * a c= carr H * a by Th4;
    then a * H * (a" * a) c= H * a by GROUP_2:34;
    then a * H * 1_G c= H * a by GROUP_1:def 5;
    hence a * H c= H * a by GROUP_2:37;
  end;
  then for a holds a * H = H * a by A1;
  hence thesis by Th117;
end;
