reserve AP for AffinPlane,
  a,a9,b,b9,c,c9,x,y,o,p,q,r,s for Element of AP,
  A,C,C9,D,K,M,N,P,T for Subset of AP;

theorem
  AP is Pappian implies AP is Desarguesian
proof
  assume
A1: AP is Pappian;
  then AP is satisfying_pap by Th9;
  then
A2: AP is satisfying_PPAP by A1,Th10;
    let A,P,C,o,a,b,c,a9,b9,c9;
    assume that
A3: o in A and
A4: o in P and
A5: o in C and
A6: o<>a and
A7: o<>b and
    o<>c and
A8: a in A and
A9: a9 in A and
A10: b in P and
A11: b9 in P and
A12: c in C and
A13: c9 in C and
A14: A is being_line and
A15: P is being_line and
A16: C is being_line and
A17: A<>P and
A18: A<>C and
A19: a,b // a9,b9 and
A20: a,c // a9,c9;
    assume
A21: not b,c // b9,c9;
    then
A22: b<>c by AFF_1:3;
A23: a<>c by A3,A5,A6,A8,A12,A14,A16,A18,AFF_1:18;
A24: not b in C
    proof
      assume
A25:  b in C;
      then b9 in C by A4,A5,A7,A10,A11,A15,A16,AFF_1:18;
      hence contradiction by A12,A13,A16,A21,A25,AFF_1:51;
    end;
A26: a<>b by A3,A4,A6,A8,A10,A14,A15,A17,AFF_1:18;
A27: a<>a9
    proof
      assume
A28:  a=a9;
      then LIN a,c,c9 by A20,AFF_1:def 1;
      then LIN c,c9,a by AFF_1:6;
      then
A29:  c =c9 or a in C by A12,A13,A16,AFF_1:25;
      LIN a,b,b9 by A19,A28,AFF_1:def 1;
      then LIN b,b9,a by AFF_1:6;
      then b=b9 or a in P by A10,A11,A15,AFF_1:25;
      hence contradiction by A3,A4,A5,A6,A8,A14,A15,A16,A17,A18,A21,A29,AFF_1:2
,18;
    end;
    set M=Line(b9,c9), N=Line(a9,b9), D=Line(a9,c9);
A30: a9<>b9
    proof
A31:  a9,c9 // c,a by A20,AFF_1:4;
      assume
A32:  a9=b9;
      then a9 in C by A3,A4,A5,A9,A11,A14,A15,A17,AFF_1:18;
      then a in C or a9=c9 by A12,A13,A16,A31,AFF_1:48;
      hence contradiction by A3,A5,A6,A8,A14,A16,A18,A21,A32,AFF_1:3,18;
    end;
    then
A33: N is being_line by AFF_1:24;
A34: a9<>c9
    proof
      assume a9=c9;
      then
A35:  a9 in P by A3,A4,A5,A9,A13,A14,A16,A18,AFF_1:18;
      a9,b9 // b,a by A19,AFF_1:4;
      then a in P by A10,A11,A15,A30,A35,AFF_1:48;
      hence contradiction by A3,A4,A6,A8,A14,A15,A17,AFF_1:18;
    end;
A36: not LIN a9,b9,c9
    proof
      assume
A37:  LIN a9,b9,c9;
      then a9,b9 // a9,c9 by AFF_1:def 1;
      then a9,b9 // a,c by A20,A34,AFF_1:5;
      then a,b // a,c by A19,A30,AFF_1:5;
      then LIN a,b,c by AFF_1:def 1;
      then LIN b,c,a by AFF_1:6;
      then b,c // b,a by AFF_1:def 1;
      then b,c // a,b by AFF_1:4;
      then
A38:  b,c // a9,b9 by A19,A26,AFF_1:5;
      LIN b9,c9,a9 by A37,AFF_1:6;
      then b9,c9 // b9,a9 by AFF_1:def 1;
      then b9,c9 // a9,b9 by AFF_1:4;
      hence contradiction by A21,A30,A38,AFF_1:5;
    end;
A39: not LIN a,b,c
    proof
      assume LIN a,b,c;
      then a,b // a,c by AFF_1:def 1;
      then a,b // a9,c9 by A20,A23,AFF_1:5;
      then a9,b9 // a9,c9 by A19,A26,AFF_1:5;
      hence contradiction by A36,AFF_1:def 1;
    end;
A40: now
      LIN o,a,a9 by A3,A8,A9,A14,AFF_1:21;
      then o,a // o,a9 by AFF_1:def 1;
      then
A41:  a9,o // a,o by AFF_1:4;
      set M=Line(b,c), N=Line(a,b), D=Line(a,c);
A42:  N is being_line by A26,AFF_1:24;
      M is being_line by A22,AFF_1:24;
      then consider K such that
A43:  o in K and
A44:  M // K by AFF_1:49;
A45:  K is being_line by A44,AFF_1:36;
A46:  a in N by A26,AFF_1:24;
A47:  b in N by A26,AFF_1:24;
A48:  b in M & c in M by A22,AFF_1:24;
      not N // K
      proof
        assume N // K;
        then N // M by A44,AFF_1:44;
        then c in N by A48,A47,AFF_1:45;
        hence contradiction by A39,A42,A46,A47,AFF_1:21;
      end;
      then consider p such that
A49:  p in N and
A50:  p in K by A42,A45,AFF_1:58;
A51:  b,c // p,o by A48,A43,A44,A50,AFF_1:39;
A52:  o<>p
      proof
        assume o=p;
        then LIN o,a,b by A42,A46,A47,A49,AFF_1:21;
        then b in A by A3,A6,A8,A14,AFF_1:25;
        hence contradiction by A3,A4,A7,A10,A14,A15,A17,AFF_1:18;
      end;
      set R=Line(a9,p);
A53:  p<>a9
      proof
        assume p=a9;
        then b in A by A8,A9,A14,A27,A42,A46,A47,A49,AFF_1:18;
        hence contradiction by A3,A4,A7,A10,A14,A15,A17,AFF_1:18;
      end;
      then
A54:  R is being_line by AFF_1:24;
      D is being_line by A23,AFF_1:24;
      then consider T such that
A55:  p in T and
A56:  D // T by AFF_1:49;
A57:  a in D & c in D by A23,AFF_1:24;
A58:  not C // T
      proof
        assume C // T;
        then C // D by A56,AFF_1:44;
        then a in C by A12,A57,AFF_1:45;
        hence contradiction by A3,A5,A6,A8,A14,A16,A18,AFF_1:18;
      end;
      T is being_line by A56,AFF_1:36;
      then consider q such that
A59:  q in C and
A60:  q in T by A16,A58,AFF_1:58;
A61:  p,q // a,c by A57,A55,A56,A60,AFF_1:39;
      then
A62:  b,q // a,o by A2,A5,A12,A16,A42,A46,A47,A49,A59,A51;
A63:  a9 in R & p in R by A53,AFF_1:24;
      assume not b,c // A;
      then
A64:  K<>A by A48,A44,AFF_1:40;
      not b,q // R
      proof
        assume b,q // R;
        then
A65:    a,o // R by A24,A59,A62,AFF_1:32;
        a,o // A by A3,A8,A14,AFF_1:40,41;
        then p in A by A6,A9,A63,A65,AFF_1:45,53;
        hence contradiction by A3,A14,A43,A45,A50,A52,A64,AFF_1:18;
      end;
      then consider r such that
A66:  r in R and
A67:  LIN b,q,r by A54,AFF_1:59;
A68:  now
        assume r=q;
        then b,r // a,o by A2,A5,A12,A16,A42,A46,A47,A49,A59,A51,A61;
        then
A69:    r,b // o,a by AFF_1:4;
        LIN o,a,a9 by A3,A8,A9,A14,AFF_1:21;
        then o,a // o,a9 by AFF_1:def 1;
        hence r,b // o,a9 by A6,A69,AFF_1:5;
      end;
      LIN q,r,b by A67,AFF_1:6;
      then q,r // q,b by AFF_1:def 1;
      then r,q // b,q by AFF_1:4;
      then r,q // a,o by A24,A59,A62,AFF_1:5;
      then
A70:  a9,o // r,q by A6,A41,AFF_1:5;
      LIN b,a,p by A42,A46,A47,A49,AFF_1:21;
      then b,a // b,p by AFF_1:def 1;
      then a,b // p,b by AFF_1:4;
      then
A71:  p,b // a9,b9 by A19,A26,AFF_1:5;
      LIN r,b,q by A67,AFF_1:6;
      then r,b // r,q by AFF_1:def 1;
      then a9,o // r,b by A70,A68,AFF_1:4,5;
      then
A72:  p,o // r,b9 by A2,A4,A10,A11,A15,A54,A63,A66,A71;
      p,q // a9,c9 by A20,A23,A61,AFF_1:5;
      then
A73:  p,o // r,c9 by A2,A5,A13,A16,A59,A54,A63,A66,A70;
      then r,c9 // r,b9 by A52,A72,AFF_1:5;
      then LIN r,c9,b9 by AFF_1:def 1;
      then LIN c9,b9,r by AFF_1:6;
      then c9,b9 // c9,r by AFF_1:def 1;
      then
A74:  r,c9 // b9,c9 by AFF_1:4;
      b,c // r,c9 by A52,A51,A73,AFF_1:5;
      then r=c9 by A21,A74,AFF_1:5;
      then p,o // b9,c9 by A72,AFF_1:4;
      hence contradiction by A21,A52,A51,AFF_1:5;
    end;
A75: b9 in N by A30,AFF_1:24;
A76: b9<>c9 by A21,AFF_1:3;
    then
A77: b9 in M & c9 in M by AFF_1:24;
    M is being_line by A76,AFF_1:24;
    then consider K such that
A78: o in K and
A79: M // K by AFF_1:49;
A80: K is being_line by A79,AFF_1:36;
A81: a9 in N by A30,AFF_1:24;
    not N // K
    proof
      assume N // K;
      then N // M by A79,AFF_1:44;
      then c9 in N by A77,A75,AFF_1:45;
      hence contradiction by A36,A33,A81,A75,AFF_1:21;
    end;
    then consider p such that
A82: p in N and
A83: p in K by A33,A80,AFF_1:58;
A84: o<>a9
    proof
      assume
A85:  o=a9;
      a9,b9 // b,a by A19,AFF_1:4;
      then a in P by A4,A10,A11,A15,A30,A85,AFF_1:48;
      hence contradiction by A3,A4,A6,A8,A14,A15,A17,AFF_1:18;
    end;
A86: o<>p
    proof
      assume o=p;
      then LIN o,a9,b9 by A33,A81,A75,A82,AFF_1:21;
      then
A87:  b9 in A by A3,A9,A14,A84,AFF_1:25;
      a9,b9 // a,b by A19,AFF_1:4;
      then b in A by A8,A9,A14,A30,A87,AFF_1:48;
      hence contradiction by A3,A4,A7,A10,A14,A15,A17,AFF_1:18;
    end;
    D is being_line by A34,AFF_1:24;
    then consider T such that
A88: p in T and
A89: D // T by AFF_1:49;
A90: T is being_line by A89,AFF_1:36;
A91: a9 in D & c9 in D by A34,AFF_1:24;
    not C // T
    proof
      assume C // T;
      then C // D by A89,AFF_1:44;
      then a9 in C by A13,A91,AFF_1:45;
      hence contradiction by A3,A5,A9,A14,A16,A18,A84,AFF_1:18;
    end;
    then consider q such that
A92: q in C and
A93: q in T by A16,A90,AFF_1:58;
A94: b9,c9 // p,o by A77,A78,A79,A83,AFF_1:39;
A95: o<>b9
    proof
      assume
A96:  o=b9;
      b9,a9 // a,b by A19,AFF_1:4;
      then b in A by A3,A8,A9,A14,A30,A96,AFF_1:48;
      hence contradiction by A3,A4,A7,A10,A14,A15,A17,AFF_1:18;
    end;
A97: b9<>q
    proof
      assume b9=q;
      then P=C by A4,A5,A11,A15,A16,A95,A92,AFF_1:18;
      hence contradiction by A10,A11,A12,A13,A15,A21,AFF_1:51;
    end;
    set R=Line(a,p);
A98: p<>a
    proof
      assume p=a;
      then b9 in A by A8,A9,A14,A27,A33,A81,A75,A82,AFF_1:18;
      hence contradiction by A3,A4,A11,A14,A15,A17,A95,AFF_1:18;
    end;
    then
A99: R is being_line by AFF_1:24;
A100: p,q // a9,c9 by A91,A88,A89,A93,AFF_1:39;
    then
A101: b9,q // a9,o by A2,A5,A13,A16,A33,A81,A75,A82,A92,A94;
A102: a in R & p in R by A98,AFF_1:24;
    not b9,c9 // A by A14,A21,A40,AFF_1:31;
    then
A103: K<>A by A77,A79,AFF_1:40;
    not b9,q // R
    proof
      assume b9,q // R;
      then
A104: a9,o // R by A101,A97,AFF_1:32;
      a9,o // A by A3,A9,A14,AFF_1:40,41;
      then p in A by A8,A84,A102,A104,AFF_1:45,53;
      hence contradiction by A3,A14,A78,A80,A83,A86,A103,AFF_1:18;
    end;
    then consider r such that
A105: r in R and
A106: LIN b9,q,r by A99,AFF_1:59;
A107: now
      assume r=q;
      then b9,r // a9,o by A2,A5,A13,A16,A33,A81,A75,A82,A92,A94,A100;
      then
A108: r,b9 // o,a9 by AFF_1:4;
      LIN o,a9,a by A3,A8,A9,A14,AFF_1:21;
      then o,a9 // o,a by AFF_1:def 1;
      hence r,b9 // o,a by A84,A108,AFF_1:5;
    end;
    LIN b9,a9,p by A33,A81,A75,A82,AFF_1:21;
    then b9,a9 // b9,p by AFF_1:def 1;
    then p,b9 // a9,b9 by AFF_1:4;
    then
A109: p,b9 // a,b by A19,A30,AFF_1:5;
    LIN o,a,a9 by A3,A8,A9,A14,AFF_1:21;
    then o,a // o,a9 by AFF_1:def 1;
    then
A110: a,o // a9,o by AFF_1:4;
    LIN q,r,b9 by A106,AFF_1:6;
    then q,r // q,b9 by AFF_1:def 1;
    then r,q // b9,q by AFF_1:4;
    then r,q // a9,o by A101,A97,AFF_1:5;
    then
A111: a,o // r,q by A84,A110,AFF_1:5;
    LIN r,b9,q by A106,AFF_1:6;
    then r,b9 // r,q by AFF_1:def 1;
    then a,o // r,b9 by A111,A107,AFF_1:4,5;
    then
A112: p,o // r,b by A2,A4,A10,A11,A15,A99,A102,A105,A109;
    p,q // a,c by A20,A34,A100,AFF_1:5;
    then
A113: p,o // r,c by A2,A5,A12,A16,A92,A99,A102,A105,A111;
    then r,c // r,b by A86,A112,AFF_1:5;
    then LIN r,c,b by AFF_1:def 1;
    then LIN c,b,r by AFF_1:6;
    then c,b // c,r by AFF_1:def 1;
    then
A114: b,c // r,c by AFF_1:4;
    b9,c9 // r,c by A86,A94,A113,AFF_1:5;
    then r=c by A21,A114,AFF_1:5;
    then b,c // p,o by A112,AFF_1:4;
    hence contradiction by A21,A86,A94,AFF_1:5;
end;
