reserve M,N for non empty multMagma,
  f for Function of M, N;
reserve M for multMagma;
reserve N,K for multSubmagma of M;
reserve M,N for non empty multMagma,
  A for Subset of M,
  f,g for Function of M,N,
  X for stable Subset of M,
  Y for stable Subset of N;

theorem Th11:
  f is multiplicative implies f.:X is stable Subset of N
proof
  assume A1: f is multiplicative;
  for v,w being Element of N st v in f.:X & w in f.:X holds v*w in f.:X
  proof
    let v,w be Element of N;
    assume v in f.:X; then
    consider v9 be object such that
    A2: v9 in dom f & v9 in X & v = f.v9 by FUNCT_1:def 6;
    assume w in f.:X; then
    consider w9 be object such that
    A3: w9 in dom f & w9 in X & w = f.w9 by FUNCT_1:def 6;
    reconsider v9,w9 as Element of M by A2,A3;
    v9*w9 in the carrier of M; then
    A4: v9*w9 in dom f by FUNCT_2:def 1;
    v9*w9 in X by A2,A3,Def10; then
    f.(v9*w9) in f.:X by A4,FUNCT_1:def 6;
    hence v*w in f.:X by A2,A3,A1,GROUP_6:def 6;
  end;
  hence f .: X is stable Subset of N by Def10;
end;
