
theorem Th11:
  for X be set, A be Subset-Family of X holds FinMeetCl A =
  FinMeetCl FinMeetCl A
proof
  let X be set, A be Subset-Family of X;
  defpred P[object,object] means
   ex A being Subset-Family of X st $1 = Intersect A &
  A = $2 & A is finite;
  thus FinMeetCl A c= FinMeetCl FinMeetCl A by Th4;
  let x be object;
  assume
A1: x in FinMeetCl FinMeetCl A;
  then reconsider x9 = x as Subset of X;
  consider Y being Subset-Family of X such that
A2: Y c= FinMeetCl A and
A3: Y is finite and
A4: x9 = Intersect Y by A1,Def3;
A5: for e being object st e in Y ex u being object st u in bool A & P[e,u]
  proof
    let e be object;
    assume
A6: e in Y;
    then reconsider e9 = e as Subset of X;
    consider Y being Subset-Family of X such that
A7: Y c=A & Y is finite & e9 = Intersect Y by A2,A6,Def3;
    take Y;
    thus thesis by A7;
  end;
  consider f being Function of Y, bool A such that
A8: for e being object st e in Y holds P[e,f.e] from FUNCT_2:sch 1(A5);
  set fz = { Intersect s where s is Subset-Family of X: s in rng f};
A9: fz c= Y
  proof
    let l be object;
    assume l in fz;
    then consider s being Subset-Family of X such that
A10: l = Intersect s and
A11: s in rng f;
    consider v being object such that
A12: v in dom f and
A13: s = f.v by A11,FUNCT_1:def 3;
    v in Y by A12,FUNCT_2:def 1;
    then P[v, f.v] by A8;
    hence thesis by A10,A12,A13,FUNCT_2:def 1;
  end;
  rng f c= bool A by RELAT_1:def 19;
  then union rng f c= union bool A by ZFMISC_1:77;
  then
A14: union rng f c= A by ZFMISC_1:81;
  then reconsider y = union rng f as Subset-Family of X by XBOOLE_1:1;
  reconsider y as Subset-Family of X;
  Y c= fz
  proof
    let l be object;
    assume
A15: l in Y;
    then consider C being Subset-Family of X such that
A16: l = Intersect C and
A17: C = f.l and
    C is finite by A8;
    l in dom f by A15,FUNCT_2:def 1;
    then C in rng f by A17,FUNCT_1:def 3;
    hence thesis by A16;
  end;
  then
A18: Y = fz by A9;
A19: x = Intersect y
  proof
    per cases;
    suppose
A20:  rng f <> {};
      rng f c= bool A & bool A c= bool bool X by RELAT_1:def 19,ZFMISC_1:67;
      then reconsider GGG = rng f as non empty Subset-Family of bool X by A20,
XBOOLE_1:1;
      reconsider GGG as non empty Subset-Family of bool X;
      fz = the set of all  Intersect b where b is Element of GGG
      proof
        hereby
          let x be object;
          assume x in fz;
          then ex s being Subset-Family of X st x = Intersect s & s in rng f;
          hence
          x in the set of all  Intersect b where b is Element of GGG;
        end;
        let x be object;
        assume
        x in the set of all  Intersect b where b is Element of GGG;
        then ex s being Element of GGG st x =Intersect s;
        hence thesis;
      end;
      hence thesis by A4,A18,Th10;
    end;
    suppose
A21:  rng f = {};
      Y = dom f by FUNCT_2:def 1;
      hence thesis by A4,A21,RELAT_1:38,41,ZFMISC_1:2;
    end;
  end;
  for V being set st V in rng f holds V is finite
  proof
    let V be set;
    assume V in rng f;
    then consider x being object such that
A22: x in dom f and
A23: V = f.x by FUNCT_1:def 3;
    x in Y by A22,FUNCT_2:def 1;
    then reconsider x as Subset of X;
    reconsider G = f.x as Subset-Family of X;
    x in Y by A22,FUNCT_2:def 1;
    then P[x,G] by A8;
    hence thesis by A23;
  end;
  then union rng f is finite by A3,FINSET_1:7;
  hence thesis by A14,A19,Def3;
end;
