
theorem Th11:
  for X be ComplexNormSpace, seq,seq1 be sequence of X holds seq
is convergent & (ex k be Nat st seq=seq1 ^\k) implies lim seq1 =lim
  seq
proof
  let X be ComplexNormSpace;
  let seq,seq1 be sequence of X;
  assume that
A1: seq is convergent and
A2: ex k be Nat st seq=seq1 ^\k;
  consider k be Nat such that
A3: seq=seq1 ^\k by A2;
A4: now
    let p be Real;
    assume 0<p;
    then consider n1 be Nat such that
A5: for m be Nat st n1<=m holds ||.seq.m-(lim seq).||<p by A1,
CLVECT_1:def 16;
    take n=n1+k;
    let m be Nat;
    assume
A6: n<=m;
    then consider l be Nat such that
A7: m=n1+k+l by NAT_1:10;
    reconsider l as Nat;
    m-k=n1+l+0 by A7;
    then consider m1 be Nat such that
A8: m1=m-k;
    now
      assume not n1<=m1;
      then m1+k<n1+k by XREAL_1:6;
      hence contradiction by A6,A8;
    end;
    then
A9: ||.seq.m1-(lim seq) .||<p by A5;
    m1+k=m by A8;
    hence ||.seq1.m-(lim seq).||<p by A3,A9,NAT_1:def 3;
  end;
  seq1 is convergent by A1,A2,Th10;
  hence thesis by A4,CLVECT_1:def 16;
end;
