reserve i,n,m for Nat,
  x,y,X,Y for set,
  r,s for Real;

theorem Th11:
  for T be non empty TopSpace for S be non-empty SetSequence of T
  st S is non-ascending for F be Subset-Family of T st F = rng S holds F is
  centered
proof
  let T be non empty TopSpace;
  let S be non-empty SetSequence of T such that
A1: S is non-ascending;
  let F be Subset-Family of T such that
A2: F = rng S;
A3: now
    defpred P[object,object] means $1=S.$2;
  :: !!!
    let G be set such that
A4: G <> {} and
A5: G c= F and
A6: G is finite;
A7: for x being object st x in G ex y being object st y in NAT & P[x,y]
    proof
      let x be object;
      assume x in G;
      then ex y being object st y in dom S & S.y=x by A2,A5,FUNCT_1:def 3;
      hence thesis;
    end;
    consider f be Function of G,NAT such that
A8: for x being object st x in G holds P[x,f.x] from FUNCT_2:sch 1(A7);
    consider i be Nat such that
A9: for j be Nat st j in rng f holds j<=i by A6,STIRL2_1:56;
A10:  i in NAT by ORDINAL1:def 12;
    dom S=NAT by FUNCT_2:def 1;
    then S.i<>{} by A10,FUNCT_1:def 9;
    then consider x being object such that
A11: x in S.i by XBOOLE_0:def 1;
A12: dom f=G by FUNCT_2:def 1;
    now
      let Y be set;
      assume
A13:  Y in G;
      then
A14:  f.Y in rng f by A12,FUNCT_1:def 3;
      reconsider fY=f.Y as Nat;
A15:  fY <= i by A9,A14;
      Y=S.fY by A8,A13;
      then S.i c= Y by A1,A15,PROB_1:def 4;
      hence x in Y by A11;
    end;
    hence meet G<>{} by A4,SETFAM_1:def 1;
  end;
  dom S=NAT by FUNCT_2:def 1;
  then F<>{} by A2,RELAT_1:42;
  hence thesis by A3,FINSET_1:def 3;
end;
