reserve X,Y,Z for set, x,y,z for object;
reserve i,j for Nat;
reserve A,B,C for Subset of X;
reserve R,R1,R2 for Relation of X;
reserve AX for Subset of [:X,X:];
reserve SFXX for Subset-Family of [:X,X:];
reserve EqR,EqR1,EqR2,EqR3 for Equivalence_Relation of X;

theorem Th11:
  for SFXX st (SFXX <> {} & for Y st Y in SFXX holds Y is
  Equivalence_Relation of X) holds meet SFXX is Equivalence_Relation of X
proof
  let SFXX such that
A1: SFXX <> {} and
A2: for Y st Y in SFXX holds Y is Equivalence_Relation of X;
  reconsider XX = meet SFXX as Relation of X;
A3: XX is_symmetric_in X
  proof
    let x,y;
    assume that
    x in X and
    y in X and
A4: [x,y] in XX;
    now
      let Y;
      assume Y in SFXX;
      then Y is Equivalence_Relation of X & [x,y] in Y by A2,A4,SETFAM_1:def 1;
      hence [y,x] in Y by Th6;
    end;
    hence thesis by A1,SETFAM_1:def 1;
  end;
A5: XX is_transitive_in X
  proof
    let x,y,z;
    assume that
    x in X and
    y in X and
    z in X and
A6: [x,y] in XX and
A7: [y,z] in XX;
    now
      let Y;
      assume
A8:   Y in SFXX;
      then
A9:   [y,z] in Y by A7,SETFAM_1:def 1;
      Y is Equivalence_Relation of X & [x,y] in Y by A2,A6,A8,SETFAM_1:def 1;
      hence [x,z] in Y by A9,Th7;
    end;
    hence thesis by A1,SETFAM_1:def 1;
  end;
  XX is_reflexive_in X
  proof
    let x such that
A10: x in X;
    for Y st Y in SFXX holds [x,x] in Y
    proof
      let Y;
      assume Y in SFXX;
      then Y is Equivalence_Relation of X by A2;
      hence thesis by A10,Th5;
    end;
    hence thesis by A1,SETFAM_1:def 1;
  end;
  then field XX = X & dom XX = X by ORDERS_1:13;
  hence thesis by A3,A5,PARTFUN1:def 2,RELAT_2:def 11,def 16;
end;
