reserve x for Real,

  Z for open Subset of REAL;

theorem
  Z c= dom (cos (#) cot) implies (cos (#) cot) is_differentiable_on Z &
  for x st x in Z holds((cos (#) cot)`|Z).x = -cos.x-cos.x/(sin.x)^2
proof
A1: for x st x in Z holds cos is_differentiable_in x by SIN_COS:63;
  assume
A2: Z c= dom (cos (#) cot);
  then
A3: Z c= dom cos /\ dom cot by VALUED_1:def 4;
  then
A4: Z c= dom cot by XBOOLE_1:18;
  for x st x in Z holds cot is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then sin.x <> 0 by A4,FDIFF_8:2;
    hence thesis by FDIFF_7:47;
  end;
  then
A5: cot is_differentiable_on Z by A4,FDIFF_1:9;
  Z c= dom cos by A3,XBOOLE_1:18;
  then
A6: cos is_differentiable_on Z by A1,FDIFF_1:9;
A7: for x st x in Z holds diff(cot, x)=-1/(sin.x)^2
  proof
    let x;
    assume x in Z;
    then sin.x<>0 by A4,FDIFF_8:2;
    hence thesis by FDIFF_7:47;
  end;
  for x st x in Z holds((cos (#) cot)`|Z).x =-cos.x-cos.x/(sin.x)^2
  proof
    let x;
    assume
A8: x in Z;
    then ((cos (#) cot)`|Z).x= diff(cos,x)*cot.x+cos.x*diff(cot,x) by A2,A5,A6,
FDIFF_1:21
      .=cot.x*(-sin.x)+cos.x*diff(cot,x) by SIN_COS:63
      .=cot.x*(-sin.x)+cos.x*(-1/(sin.x)^2) by A7,A8
      .=(cos.x/sin.x)*(-sin.x/1)-cos.x/(sin.x)^2 by A4,A8,RFUNCT_1:def 1
      .=-cos.x*(sin.x/sin.x)-cos.x/(sin.x)^2
      .=-cos.x*1-cos.x/(sin.x)^2 by A4,A8,FDIFF_8:2,XCMPLX_1:60
      .=-cos.x-cos.x/(sin.x)^2;
    hence thesis;
  end;
  hence thesis by A2,A5,A6,FDIFF_1:21;
end;
