
theorem Th11:
  for M being non empty MetrSpace, x being Point of TopSpaceMetr(M),
      x9 being Point of M st x = x9
  ex f being sequence of Balls(x) st
  for n being Element of NAT holds f.n = Ball(x9,1/(n+1))
proof
  let M be non empty MetrSpace, x be Point of TopSpaceMetr(M),
  x9 be Point of M;
  assume
A1: x = x9;
  set B = Balls(x);
  consider x9 being Point of M such that
A2: x9 = x & B = { Ball(x9,1/n) where n is Nat: n <> 0 } by Def1;
  defpred P[object,object] means
   ex n9 being Element of NAT st $1=n9 &
  $2 = Ball(x9,1/(n9+1));
A3: for n being object st n in NAT ex O being object st O in B & P[n,O]
  proof
    let n be object;
    assume n in NAT;
    then reconsider n as Element of NAT;
    take Ball(x9,1/(n+1));
    thus thesis by A2;
  end;
  consider f being Function such that
A4: dom f = NAT & rng f c= B and
A5: for n being object st n in NAT holds P[n,f.n] from FUNCT_1:sch 6(A3);
  reconsider f as sequence of B by A4,FUNCT_2:2;
  take f;
  let n be Element of NAT;
  P[n,f.n] by A5;
  hence thesis by A2,A1;
end;
