
theorem Th11:
  for T1,T2 being non empty TopSpace, f being Function of T1,T2
holds f is continuous implies for S1 being sequence of T1, S2 being sequence of
  T2 st S2=f*S1 holds f.:(Lim S1) c= Lim S2
proof
  let T1,T2 be non empty TopSpace, f be Function of T1,T2;
  assume
A1: f is continuous;
  let S1 be sequence of T1, S2 be sequence of T2;
  assume
A2: S2=f*S1;
  let y be object;
  assume
A3: y in f.:(Lim S1);
  then reconsider y9=y as Point of T2;
  S2 is_convergent_to y9
  proof
    let U2 be Subset of T2;
    assume that
A4: U2 is open and
A5: y9 in U2;
    consider x being object such that
A6: x in dom f and
A7: x in Lim S1 and
A8: y = f.x by A3,FUNCT_1:def 6;
A9: x in f"U2 by A5,A6,A8,FUNCT_1:def 7;
    reconsider U1=f"U2 as Subset of T1;
    [#]T2 <> {};
    then
A10: U1 is open by A1,A4,TOPS_2:43;
    reconsider x as Point of T1 by A6;
    S1 is_convergent_to x by A7,FRECHET:def 5;
    then consider n being Nat such that
A11: for m being Nat st n <= m holds S1.m in f"U2 by A10,A9;
    take n;
    let m be Nat;
A12:  m in NAT by ORDINAL1:def 12;
    assume n <= m;
    then S1.m in f"U2 by A11;
    then
A13: f.(S1.m) in U2 by FUNCT_1:def 7;
    dom S1 = NAT by FUNCT_2:def 1;
    hence S2.m in U2 by A2,A13,FUNCT_1:13,A12;
  end;
  hence thesis by FRECHET:def 5;
end;
