 reserve a,b,c,x for Real;

theorem
  c - b > 0 implies
    rng ((AffineMap (-1/(c-b),c/(c-b)) | ].b,c.])) = [.0,1.[
  proof
    set f = AffineMap (-1/(c-b),c/(c-b));
    set g = f | ].b,c.];
    assume
A0: c - b > 0;
    thus rng g c= [.0,1.[
    proof
      let y be object;
      assume
Y0:   y in rng g; then
      consider x being object such that
A1:   x in dom g and
A2:   y = g.x by FUNCT_1:def 3;
Y1:   x in ].b,c.] by A1,RELAT_1:57;
      reconsider xx = x as Real by A1;
      reconsider yy = y as Real by Y0;
S4:   y = f.xx by FUNCT_1:47,A1,A2;
A4:   b < xx by Y1,XXREAL_1:2;
S2:   f.b = 1 by Cb1,A0;
S5:   f.b > f.xx by A4,FCONT_1:52,A0;
      xx <= c by Y1,XXREAL_1:2; then
S6:   f.xx >= f.c by A0,FCONT_1:54;
      f.c = 0 by Cb2;
      hence thesis by S4,S2,S5,S6;
    end;
    let y be object;
    assume
V1: y in [.0,1.[; then
    reconsider yy = y as Real;
    set A = -1 / (c-b);
    set B = c / (c-b);
L2: (f qua Function)" = AffineMap (A",-B/A) by A0,FCONT_1:56; then
L3: (f qua Function)".0 = A" * 0 + -B/A by FCONT_1:def 4
     .= -((c / (c-b))/((-1) / (c-b))) by XCMPLX_1:187
     .= -(c / -1) by XCMPLX_1:55,A0
     .= c;
X1: -B/A = -((c / (c-b))/((-1) / (c-b))) by XCMPLX_1:187
     .= -(c / -1) by XCMPLX_1:55,A0
     .= c;
L4: (f qua Function)".1 = A" * 1 + -B/A by FCONT_1:def 4,L2
     .= 1/A + -B/A by XCMPLX_1:215
     .= 1/((-1)/(c-b)) + c by XCMPLX_1:187,X1
     .= (c-b)/(-1) + c by XCMPLX_1:57
     .= b;
    set x = (f qua Function)".yy;
    reconsider xx = x as Real by L2;
J2: 0 <= yy & yy < 1 by XXREAL_1:3,V1; then
J3: c >= xx by FCONT_1:54,L2,A0,L3;
    xx > b by FCONT_1:52,L2,A0,J2,L4; then
J4: x in ].b,c.] by J3;
j5: dom f = REAL by FUNCT_2:def 1;
T1: x in dom g by J4,j5,RELAT_1:57;
    rng f = REAL by FCONT_1:55,A0; then
S2: yy in rng f by XREAL_0:def 1;
    set ff = (f qua Function)";
    g.(ff.yy) = f.(ff.yy) by FUNCT_1:49,J4
       .= yy by A0,S2,FUNCT_1:35;
    hence thesis by T1,FUNCT_1:def 3;
  end;
