reserve p,p1,p2,q for Point of TOP-REAL 2,
  f,f1,f2,g,g1,g2 for FinSequence of TOP-REAL 2,
  r,s for Real,

  n,m,i,j,k for Nat,
  G for Go-board,
  x for set;

theorem Th11:
  f is special implies
  for n being Nat st n in dom f & n+1 in dom f
for i,j,m,k being Nat
  st [i,j] in Indices G & [m,k] in Indices G & f/.n=G*(i,j) & f/.(n+1
  )=G*(m,k) holds i=m or k=j
proof
  assume
A1: f is special;
  let n be Nat;
  assume n in dom f & n+1 in dom f;
  then
A2: 1 <= n & n +1 <= len f by FINSEQ_3:25;
  let i,j,m,k be Nat such that
A3: [i,j] in Indices G and
A4: [m,k] in Indices G and
A5: f/.n=G*(i,j) & f/.(n+1)=G*(m,k);
  reconsider cj = Col(G,j), lm = Line(G,m) as FinSequence of TOP-REAL 2;
  set xj = X_axis(cj), yj = Y_axis(cj), xm = X_axis(lm), ym = Y_axis(lm);
  len cj=len G by MATRIX_0:def 8;
  then
A6: dom cj = dom G by FINSEQ_3:29;
  assume that
A7: i<>m and
A8: k<>j;
A9: len xm=len lm & dom xm=Seg len xm by FINSEQ_1:def 3,GOBOARD1:def 1;
A10: len xj=len cj by GOBOARD1:def 1;
  then
A11: dom xj = dom cj by FINSEQ_3:29;
A12: Indices G = [:dom G,Seg width G:] by MATRIX_0:def 4;
  then
A13: i in dom G by A3,ZFMISC_1:87;
  then cj/.i = cj.i by A6,PARTFUN1:def 6;
  then
A14: G*(i,j)=cj/.i by A13,MATRIX_0:def 8;
  then
A15: xj.i=G*(i,j)`1 by A13,A6,A11,GOBOARD1:def 1;
A16: m in dom G by A4,A12,ZFMISC_1:87;
  then cj/.m = cj.m by A6,PARTFUN1:def 6;
  then
A17: G*(m,j)=cj/.m by A16,MATRIX_0:def 8;
  then
A18: xj.m=G*(m,j)`1 by A16,A6,A11,GOBOARD1:def 1;
A19: ym is increasing by A16,GOBOARD1:def 6;
A20: xm is constant by A16,GOBOARD1:def 4;
A21: dom yj=Seg len yj by FINSEQ_1:def 3;
A22: dom xj=Seg len xj & len yj=len cj by FINSEQ_1:def 3,GOBOARD1:def 2;
  then
A23: yj.m=G*(m,j)`2 by A16,A10,A21,A6,A11,A17,GOBOARD1:def 2;
A24: j in Seg width G by A3,A12,ZFMISC_1:87;
  then
A25: xj is increasing by GOBOARD1:def 7;
A26: len lm=width G by MATRIX_0:def 7;
  then
A27: dom lm = Seg width G by FINSEQ_1:def 3;
  then lm/.j = lm.j by A24,PARTFUN1:def 6;
  then
A28: G*(m,j)=lm/.j by A24,MATRIX_0:def 7;
  then
A29: xm.j=G*(m,j)`1 by A24,A26,A9,GOBOARD1:def 1;
A30: k in Seg width G by A4,A12,ZFMISC_1:87;
  then lm/.k = lm.k by A27,PARTFUN1:def 6;
  then
A31: G*(m,k)=lm/.k by A30,MATRIX_0:def 7;
  then
A32: xm.k=G*(m,k)`1 by A30,A26,A9,GOBOARD1:def 1;
A33: yj is constant by A24,GOBOARD1:def 5;
A34: len ym=len lm & dom ym=Seg len ym by FINSEQ_1:def 3,GOBOARD1:def 2;
  then
A35: ym.j=G*(m,j)`2 by A24,A26,A28,GOBOARD1:def 2;
A36: ym.k=G*(m,k)`2 by A30,A26,A34,A31,GOBOARD1:def 2;
A37: yj.i=G*(i,j)`2 by A13,A10,A22,A21,A6,A11,A14,GOBOARD1:def 2;
  now
    per cases by A1,A5,A2;
    suppose
A38:  G*(i,j)`1=G*(m,k)`1;
      now
        per cases by A7,XXREAL_0:1;
        suppose
          i>m;
          then G*(m,j)`1<G*(i,j)`1 by A13,A16,A6,A11,A25,A15,A18,SEQM_3:def 1;
          hence contradiction by A24,A30,A26,A9,A20,A29,A32,A38,SEQM_3:def 10;
        end;
        suppose
          i<m;
          then G*(m,j)`1>G*(i,j)`1 by A13,A16,A6,A11,A25,A15,A18,SEQM_3:def 1;
          hence contradiction by A24,A30,A26,A9,A20,A29,A32,A38,SEQM_3:def 10;
        end;
      end;
      hence contradiction;
    end;
    suppose
A39:  G*(i,j)`2=G*(m,k)`2;
      now
        per cases by A8,XXREAL_0:1;
        suppose
          k>j;
          then G*(m,j)`2<G*(m,k)`2 by A24,A30,A26,A34,A19,A35,A36,SEQM_3:def 1;
          hence contradiction by A13,A16,A10,A22,A21,A6,A11,A33,A37,A23,A39,
SEQM_3:def 10;
        end;
        suppose
          k<j;
          then G*(m,j)`2>G*(m,k)`2 by A24,A30,A26,A34,A19,A35,A36,SEQM_3:def 1;
          hence contradiction by A13,A16,A10,A22,A21,A6,A11,A33,A37,A23,A39,
SEQM_3:def 10;
        end;
      end;
      hence contradiction;
    end;
  end;
  hence contradiction;
end;
