reserve p,q for Point of TOP-REAL 2,
  i,i1,i2,j,j1,j2,k for Nat,
  r,s for Real,
  G for Matrix of TOP-REAL 2;

theorem Th11:
  for f being non empty FinSequence of TOP-REAL 2
  for n being Nat st n in dom f
  ex i,j st [i,j] in Indices GoB f & f/.n = (GoB f)*(i,j)
proof
  let f be non empty FinSequence of TOP-REAL 2;
  let n be Nat such that
A1: n in dom f;
A2: GoB f = GoB(Incr X_axis f,Incr Y_axis f) by GOBOARD2:def 2;
  set x = (f/.n)`1, y = (f/.n)`2;
A3: n in dom X_axis f by A1,Lm1;
  then (X_axis f).n = x by GOBOARD1:def 1;
  then x in rng X_axis f by A3,FUNCT_1:def 3;
  then x in rng Incr X_axis f by SEQ_4:def 21;
  then consider i being Nat such that
A4: i in dom Incr X_axis f and
A5: (Incr X_axis f).i = x by FINSEQ_2:10;
A6: n in dom Y_axis f by A1,Lm2;
  then (Y_axis f).n = y by GOBOARD1:def 2;
  then y in rng Y_axis f by A6,FUNCT_1:def 3;
  then y in rng Incr Y_axis f by SEQ_4:def 21;
  then consider j being Nat such that
A7: j in dom Incr Y_axis f and
A8: (Incr Y_axis f).j = y by FINSEQ_2:10;
  reconsider i,j as Nat;
  take i,j;
  i in Seg len Incr X_axis f by A4,FINSEQ_1:def 3;
  then i in Seg len GoB(Incr X_axis f,Incr Y_axis f) by GOBOARD2:def 1;
  then
A9: i in dom GoB f by A2,FINSEQ_1:def 3;
  j in Seg len Incr Y_axis f by A7,FINSEQ_1:def 3;
  then j in Seg width GoB(Incr X_axis f,Incr Y_axis f) by GOBOARD2:def 1;
  then [i,j] in [:dom GoB f, Seg width GoB f:] by A2,A9,ZFMISC_1:87;
  hence
A10: [i,j] in Indices GoB f by MATRIX_0:def 4;
  thus f/.n = |[Incr(X_axis f).i,Incr(Y_axis f).j]| by A5,A8,EUCLID:53
    .= (GoB f)*(i,j) by A2,A10,GOBOARD2:def 1;
end;
