reserve i, j, n for Nat,
  f for non constant standard special_circular_sequence,
  g for clockwise_oriented non constant standard special_circular_sequence,
  p, q for Point of TOP-REAL 2,
  P for Subset of TOP-REAL 2,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board;

theorem
  for r, t being Real holds r > 0 & t > 0 implies ex n being
  Nat st 1 < n & dist(Gauge(C,n)*(1,1),Gauge(C,n)*(1,2)) < r & dist(
  Gauge(C,n)*(1,1),Gauge(C,n)*(2,1)) < t
proof
  let r, t be Real;
  assume that
A1: r > 0 and
A2: t > 0;
  set n = N-bound C, e = E-bound C, s = S-bound C, w = W-bound C;
  set a = |.[\ log(2,(n-s)/r) /].| + 1, b = |.[\ log(2,(e-w)/t) /].| + 1;
  take i = max(a,b)+1;
A3: 2 to_power i > 0 by POWER:34;
  then
A4: 2|^i > 0 by POWER:41;
  [\ log(2,(n-s)/r) /] <= |.[\ log(2,(n-s)/r) /].| by ABSVALUE:4;
  then
A5: [\ log(2,(n-s)/r) /] + 1 <= a by XREAL_1:6;
  [\ log(2,(n-s)/r) /] > log(2,(n-s)/r) - 1 by INT_1:def 6;
  then [\ log(2,(n-s)/r) /] + 1 > log(2,(n-s)/r) - 1 + 1 by XREAL_1:6;
  then
A6: a > log(2,(n-s)/r) - 1 + 1 by A5,XXREAL_0:2;
  a <= max(a,b) by XXREAL_0:25;
  then
A7: a+1 <= max(a,b)+1 by XREAL_1:6;
  a < a+1 by XREAL_1:29;
  then i > a by A7,XXREAL_0:2;
  then i > log(2,(n-s)/r) by A6,XXREAL_0:2;
  then log(2,2 to_power i) > log(2,(n-s)/r) by A3,POWER:def 3;
  then 2 to_power i > (n-s)/r by A3,PRE_FF:10;
  then 2|^i > (n-s)/r by POWER:41;
  then 2|^i * r > (n-s)/r * r by A1,XREAL_1:68;
  then 2|^i * r > n-s by A1,XCMPLX_1:87;
  then 2|^i * r / 2|^i > (n-s) / 2|^i by A4,XREAL_1:74;
  then
A8: (n-s)/2|^i < r by A4,XCMPLX_1:89;
  a >= 0+1 & max(a,b) >= a by XREAL_1:7,XXREAL_0:25;
  then max(a,b) >= 1 by XXREAL_0:2;
  then max(a,b)+1 >= 1+1 by XREAL_1:7;
  hence 1 < i by XXREAL_0:2;
A9: len Gauge(C,i) >= 4 by JORDAN8:10;
  then
A10: 1 <= len Gauge(C,i) by XXREAL_0:2;
  [\ log(2,(e-w)/t) /] <= |.[\ log(2,(e-w)/t) /].| by ABSVALUE:4;
  then
A11: [\ log(2,(e-w)/t) /] + 1 <= b by XREAL_1:6;
  [\ log(2,(e-w)/t) /] > log(2,(e-w)/t) - 1 by INT_1:def 6;
  then [\ log(2,(e-w)/t) /] + 1 > log(2,(e-w)/t) - 1 + 1 by XREAL_1:6;
  then
A12: b > log(2,(e-w)/t) - 1 + 1 by A11,XXREAL_0:2;
  b <= max(a,b) by XXREAL_0:25;
  then
A13: b+1 <= max(a,b)+1 by XREAL_1:6;
  b < b+1 by XREAL_1:29;
  then i > b by A13,XXREAL_0:2;
  then i > log(2,(e-w)/t) by A12,XXREAL_0:2;
  then log(2,2 to_power i) > log(2,(e-w)/t) by A3,POWER:def 3;
  then 2 to_power i > (e-w)/t by A3,PRE_FF:10;
  then 2|^i > (e-w)/t by POWER:41;
  then 2|^i * t > (e-w)/t * t by A2,XREAL_1:68;
  then 2|^i * t > e-w by A2,XCMPLX_1:87;
  then 2|^i * t / 2|^i > (e-w) / 2|^i by A4,XREAL_1:74;
  then
A14: (e-w)/2|^i < t by A4,XCMPLX_1:89;
A15: len Gauge(C,i) = width Gauge(C,i) by JORDAN8:def 1;
  then
A16: [1,1] in Indices Gauge(C,i) by A10,MATRIX_0:30;
A17: 1+1 <= width Gauge(C,i) by A15,A9,XXREAL_0:2;
  then
A18: [1,1+1] in Indices Gauge(C,i) by A10,MATRIX_0:30;
  [1+1,1] in Indices Gauge(C,i) by A15,A10,A17,MATRIX_0:30;
  hence thesis by A8,A14,A16,A18,Th9,Th10;
end;
