reserve G for strict Group,
  a,b,x,y,z for Element of G,
  H,K for strict Subgroup of G,
  p for Element of NAT,
  A for Subset of G;

theorem Th11:
  b is not being_of_order_0 implies gr {b} is finite
proof
  assume
A1: b is not being_of_order_0;
  then
A2: ord b <> 0 by GROUP_1:def 11;
  deffunc B(Nat) = b |^ $1;
  consider f being FinSequence such that
A3: len f = ord b & for i being Nat st i in dom f holds
  f.i = B(i) from FINSEQ_1:sch 2;
A4: dom f = Seg ord b by A3,FINSEQ_1:def 3;
  the carrier of gr {b} c= rng f
  proof
    let x be object;
    assume x in the carrier of gr {b};
    then
A5: x in gr {b};
    then x in G by GROUP_2:40;
    then reconsider a = x as Element of G;
    consider m being Integer such that
A6: a = b|^m by A5,GR_CY_1:5;
    set k = m mod ord b;
    reconsider k as Element of NAT by INT_1:3,NEWTON:64;
A7: a = b|^k by A1,A6,Th10;
    per cases;
    suppose
A8:   k = 0;
      ord b >= 0+1 by A2,NAT_1:13;
      then
A9:   ord b in Seg ord b by FINSEQ_1:1;
      a = 1_G by A7,A8,GROUP_1:25
        .= b |^ ord b by A1,GROUP_1:def 11
        .= f.ord b by A3,A4,A9;
      hence thesis by A4,A9,FUNCT_1:def 3;
    end;
    suppose
A10:  k <> 0;
A11:  k < ord b by A2,NEWTON:65;
      k >= 0+1 by A10,NAT_1:13;
      then
A12:  k in Seg ord b by A11,FINSEQ_1:1;
      then a = f.k by A3,A4,A7;
      hence thesis by A4,A12,FUNCT_1:def 3;
    end;
  end;
  hence the carrier of gr {b} is finite;
end;
