reserve r,x,x0,a,b for Real;
reserve n,m for Element of NAT;
reserve A for non empty closed_interval Subset of REAL;
reserve Z for open Subset of REAL;

theorem Th11:
  (AffineMap(1,0))(#)sinh-cosh is_differentiable_on REAL & for x
  holds (((AffineMap(1,0))(#)sinh-cosh)`|REAL).x=x*cosh.x
proof
A1: dom ((AffineMap(1,0))(#)sinh-cosh) = [#]REAL by FUNCT_2:def 1;
A2: dom (AffineMap(1,0)) = [#]REAL & for x st x in REAL holds AffineMap(1,0)
  .x=1 *x + 0 by FCONT_1:def 4,FUNCT_2:def 1;
  then
A3: AffineMap(1,0) is_differentiable_on REAL by FDIFF_1:23;
A4: dom ((AffineMap(1,0))(#)sinh) = [#]REAL by FUNCT_2:def 1;
  then
A5: ((AffineMap(1,0))(#)sinh) is_differentiable_on REAL by A3,FDIFF_1:21
,SIN_COS2:34;
 hence (AffineMap(1,0))(#)sinh-cosh is_differentiable_on REAL
   by A1,FDIFF_1:19,SIN_COS2:35;
A6: for x st x in REAL holds (((AffineMap(1,0))(#)sinh)`|REAL).x = sinh.x+x*
  cosh.x
  proof
    let x;
    assume
A7: x in REAL;
    (((AffineMap(1,0))(#)sinh)`|REAL).x = sinh.x*diff((AffineMap(1,0)),x)+
    ((AffineMap(1,0)).x) *diff(sinh,x) by A4,A3,FDIFF_1:21,SIN_COS2:34,A7
      .= sinh.x*(((AffineMap(1,0))`|REAL).x) +((AffineMap(1,0)).x)*diff(sinh
    ,x) by A3,FDIFF_1:def 7,A7
      .= sinh.x*1+((AffineMap(1,0)).x)*diff(sinh,x) by A2,FDIFF_1:23,A7
      .= sinh.x+((AffineMap(1,0)).x)*(cosh.x) by SIN_COS2:34
      .= sinh.x+(1*x + 0)*cosh.x by FCONT_1:def 4
      .= sinh.x+x*cosh.x;
    hence thesis;
  end;
A8:
  for x st x in REAL holds (((AffineMap(1,0))(#)sinh-cosh)`|REAL).x = x*(
  cosh.x)
  proof
    let x;
    assume
A9: x in REAL;
    (((AffineMap(1,0))(#)sinh - cosh)`|REAL).x = diff(((AffineMap(1,0))(#)
    sinh),x) - diff(cosh,x) by A1,A5,FDIFF_1:19,SIN_COS2:35,A9
      .= (((AffineMap(1,0))(#)sinh)`|REAL).x - diff(cosh,x)
by A5,FDIFF_1:def 7,A9
      .= sinh.x+x*cosh.x-diff(cosh,x) by A6,A9
      .= sinh.x+x*cosh.x-sinh.x by SIN_COS2:35
      .= x*cosh.x;
    hence thesis;
  end;
  let x;
   x in REAL by XREAL_0:def 1;
  hence thesis by A8;
end;
