 reserve a,x for Real;
 reserve n for Nat;
 reserve A for non empty closed_interval Subset of REAL;
 reserve f,f1 for PartFunc of REAL,REAL;
 reserve Z for open Subset of REAL;

theorem Th11:
  Z c= dom (cosec*tan) implies -cosec*tan is_differentiable_on Z &
  for x st x in Z holds ((-cosec*tan)`|Z).x
  = cos.(tan.x)/(cos.x)^2/(sin.(tan.x))^2
proof
  assume
A1:Z c= dom (cosec*tan);
then A2:Z c= dom (-cosec*tan) by VALUED_1:8;
A3:cosec*tan is_differentiable_on Z by A1,FDIFF_9:40;
  dom (cosec*tan) c= dom tan by RELAT_1:25; then
A4: Z c= dom tan by A1;
A5:(-1)(#)(cosec*tan) is_differentiable_on Z by A2,A3,FDIFF_1:20;
A6:for x st x in Z holds sin.(tan.x)<>0
  proof
    let x;
    assume x in Z;
    then tan.x in dom cosec by A1,FUNCT_1:11;
    hence thesis by RFUNCT_1:3;
  end;
  for x st x in Z holds ((-cosec*tan)`|Z).x
  = cos.(tan.x)/(cos.x)^2/(sin.(tan.x))^2
    proof
      let x;
      assume
A7:   x in Z; then
A8:   cos.x<>0 by A4,FDIFF_8:1; then
A9:   tan is_differentiable_in x by FDIFF_7:46;
A10:   sin.(tan.x)<>0 by A6,A7;then
A11:  cosec is_differentiable_in tan.x by FDIFF_9:2;
A12:  cosec*tan is_differentiable_in x by A3,A7,FDIFF_1:9;
      ((-cosec*tan)`|Z).x=diff(-cosec*tan,x) by A5,A7,FDIFF_1:def 7
    .=(-1)*(diff(cosec*tan,x)) by A12,FDIFF_1:15
    .=(-1)*(diff(cosec, tan.x)*diff(tan,x)) by A9,A11,FDIFF_2:13
    .=(-1)*((-cos.(tan.x)/(sin.(tan.x))^2) * diff(tan,x)) by A10,FDIFF_9:2
    .=(-1)*((1/(cos.x)^2)*(-cos.(tan.x)/(sin.(tan.x))^2)) by A8,FDIFF_7:46
    .=cos.(tan.x)/(cos.x)^2/(sin.(tan.x))^2;
     hence thesis;
    end;
    hence thesis by A5;
end;
