reserve i,j,k,m,n for Nat,
  f for FinSequence of the carrier of TOP-REAL 2,
  G for Go-board;
reserve C for compact non vertical non horizontal non empty
  being_simple_closed_curve Subset of TOP-REAL 2,
  p for Point of TOP-REAL 2,
  i1, j1,i2,j2 for Nat;

theorem Th11: :: symmetric to JORDAN8:9
  for f being FinSequence of TOP-REAL 2 st f is_sequence_on G & (
  ex i,j st [i,j] in Indices G & p = G*(i,j)) & (for i1,j1,i2,j2 st [i1,j1] in
Indices G & [i2,j2] in Indices G & p = G*(i1,j1) & f/.1 = G*(i2,j2)
  holds |.i2-i1.|+|.j2-j1.| = 1) holds <*p*>^f is_sequence_on G
proof
  let f be FinSequence of TOP-REAL 2 such that
A1: f is_sequence_on G and
A2: ex i,j st [i,j] in Indices G & p = G*(i,j) and
A3: for i1,j1,i2,j2 st [i1,j1] in Indices G & [i2,j2] in Indices G & p =
  G*(i1,j1) & f/.1 = G*(i2,j2) holds |.i2-i1.|+|.j2-j1.| = 1;
A4: now
    let m,k,i,j such that
A5: [m,k] in Indices G & [i,j] in Indices G & <*p*>/.(len <*p*>)=G*(m
    ,k) & f/.1=G*(i,j) and
A6: len <*p*> in dom <*p*> and
    1 in dom f;
    len <*p*> = 1 by FINSEQ_1:40;
    then <*p*>.(len <*p*>) = p by FINSEQ_1:40;
    then <*p*>/.(len <*p*>) = p by A6,PARTFUN1:def 6;
    then |.i-m.|+|.j-k.|=1 by A3,A5;
    hence 1 = |.m-i.|+|.j-k.| by UNIFORM1:11
      .= |.m-i.|+|.k-j.| by UNIFORM1:11;
  end;
A7: now
    let n such that
A8: n in dom(<*p*>^f);
    per cases by A8,FINSEQ_1:25;
    suppose
A9:   n in dom <*p*>;
      consider i,j such that
A10:  [i,j] in Indices G and
A11:  p = G*(i,j) by A2;
      take i,j;
      thus [i,j] in Indices G by A10;
      n in Seg 1 by A9,FINSEQ_1:38;
      then 1 <= n & n <= 1 by FINSEQ_1:1;
      then n=1 by XXREAL_0:1;
      then <*p*>.n = p by FINSEQ_1:40;
      then <*p*>/.n = p by A9,PARTFUN1:def 6;
      hence (<*p*>^f)/.n = G*(i,j) by A9,A11,FINSEQ_4:68;
    end;
    suppose
      ex l be Nat st l in dom f & n = (len <*p*>) + l;
      then consider l be Nat such that
A12:  l in dom f and
A13:  n = (len <*p*>) + l;
      consider i,j such that
A14:  [i,j] in Indices G and
A15:  f/.l = G*(i,j) by A1,A12,GOBOARD1:def 9;
      take i,j;
      thus [i,j] in Indices G by A14;
      thus (<*p*>^f)/.n = G*(i,j) by A12,A13,A15,FINSEQ_4:69;
    end;
  end;
A16: now
    let n;
    assume that
A17: n in dom <*p*> and
A18: n+1 in dom <*p*>;
    n+1 <= len <*p*> by A18,FINSEQ_3:25;
    then
A19: n+1 <= 1 by FINSEQ_1:39;
    1 <= n by A17,FINSEQ_3:25;
    then 1+1 <= n+1 by XREAL_1:6;
    hence
    for m,k,i,j st [m,k] in Indices G & [i,j] in Indices G & <*p*>/.n=G*(
    m,k) & <*p*>/.(n+1)=G*(i,j) holds |.m-i.|+|.k-j.|=1 by A19,XXREAL_0:2;
  end;
  for n st n in dom f & n+1 in dom f holds for m,k,i,j st [m,k] in Indices
G & [i,j] in Indices G & f/.n=G*(m,k) & f/.(n+1)=G*(i,j)
   holds |.m-i.|+|.k-j.|=1 by A1,GOBOARD1:def 9;
  then
  for n st n in dom(<*p*>^f) & n+1 in dom(<*p*>^f) holds for m,k,i,j st [
m,k] in Indices G & [i,j] in Indices G & (<*p*>^f)/.n =G*(m,k) & (<*p*>^f)/.(n+
  1)=G*(i,j) holds |.m-i.|+|.k-j.|=1 by A16,A4,GOBOARD1:24;
  hence thesis by A7,GOBOARD1:def 9;
end;
