reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;

theorem Th5:
  for n being Nat, A be Subset of TOP-REAL n
   holds A is bounded iff A is bounded Subset of Euclid n
  proof let n be Nat, A be Subset of TOP-REAL n;
    reconsider z = 0*n as Element of Euclid n;
   thus A is bounded implies A is bounded Subset of Euclid n
    proof assume
A1:     A is bounded;
      reconsider B = A as Subset of Euclid n by EUCLID:67;
      z = 0.TOP-REAL n by EUCLID:70;
      then reconsider V = Ball(z,1) as a_neighborhood of 0.TOP-REAL n
               by GOBOARD6:2;
      consider s being Real such that
A2:   s > 0 and
A3:   for t being Real
        st t > s holds A c= t*V by A1;
      set r = s+1;
    0 < r by A2;
      then r*V = Ball(z,r*1) by Lm2;
      then B c= Ball(z,r) by A3,XREAL_1:29;
     hence A is bounded Subset of Euclid n by A2,METRIC_6:def 3;
    end;
   assume
A4:    A is bounded Subset of Euclid n;
    then reconsider B = A as Subset of Euclid n;
    consider r1 being Real such that
A5:  0 < r1 and
A6:  B c= Ball(z,r1) by A4,METRIC_6:29;
   let V be a_neighborhood of 0.TOP-REAL n;
  0.TOP-REAL n = 0*n by EUCLID:70;
    then z in Int V by CONNSP_2:def 1;
    then consider r2 being Real such that
A7:  r2 > 0 and
A8:  Ball(z,r2) c= V by GOBOARD6:5;
    reconsider r2 as Real;
   take s = r1/r2;
   thus
A9:   s > 0 by A5,A7,XREAL_1:139;
   let t;
    reconsider BA = Ball(z,r2)  as Subset of TOP-REAL n by EUCLID:67;
   s*r2 = r1 by A7,XCMPLX_1:87;
   then
A10: A c= s*BA by A6,A9,Lm2;
   assume t > s;
   then s*BA c= t*BA by A9,Lm3;
   then
A11: A c= t*BA by A10;
   t*BA c= t*V by A8,CONVEX1:39;
   hence A c= t*V by A11;
  end;
