reserve p,p1,p2,p3,q for Point of TOP-REAL 2;

theorem Th11:
  for P being compact non empty Subset of TOP-REAL 2, q1,q2 being
  Point of TOP-REAL 2 st P is being_simple_closed_curve & LE q1,q2,P & q1 <>
  W-min P & q2 <> W-min P holds Segment(q1,q2,P)/\ Segment(q2,W-min P,P)={q2}
proof
  let P be compact non empty Subset of TOP-REAL 2, q1,q2 be Point of TOP-REAL
  2;
  set q3 = W-min P;
  assume that
A1: P is being_simple_closed_curve and
A2: LE q1,q2,P and
A3: q1<>q3 and
A4: not q2=W-min(P);
  thus Segment(q1,q2,P)/\ Segment(q2,W-min P,P) c= {q2}
  proof
    let x be object;
    assume
A5: x in Segment(q1,q2,P)/\ Segment(q2,q3,P);
    then x in Segment(q2,q3,P) by XBOOLE_0:def 4;
    then x in {p1: LE q2,p1,P or q2 in P & p1=W-min P} by Def1;
    then consider p1 such that
A6: p1=x and
A7: LE q2,p1,P or q2 in P & p1=W-min P;
    x in Segment(q1,q2,P) by A5,XBOOLE_0:def 4;
    then p1 in {p: LE q1,p,P & LE p,q2,P} by A4,A6,Def1;
    then
A8: ex p st p=p1 & LE q1,p,P & LE p,q2,P;
    per cases by A7;
    suppose
      LE q2,p1,P;
      then x=q2 by A1,A6,A8,JORDAN6:57;
      hence thesis by TARSKI:def 1;
    end;
    suppose
      q2 in P & p1=W-min(P);
      hence thesis by A1,A3,A8,Th2;
    end;
  end;
  let x be object;
  assume x in {q2};
  then
A9: x=q2 by TARSKI:def 1;
  q2 in P by A1,A2,Th5;
  then
A10: x in Segment(q2,q3,P) by A1,A9,Th7;
  x in Segment(q1,q2,P) by A1,A2,A9,Th6;
  hence thesis by A10,XBOOLE_0:def 4;
end;
