reserve x,y for object,
  N for Element of NAT,
  c,i,j,k,m,n for Nat,
  D for non empty set,
  s for Element of 2Set Seg (n+2),
  p for Element of Permutations(n) ,
  p1, q1 for Element of Permutations(n+1),
  p2 for Element of Permutations(n +2),
  K for Field,
  a for Element of K,
  f for FinSequence of K,
  A for (Matrix of K),
  AD for Matrix of n,m,D,
  pD for FinSequence of D,
  M for Matrix of n,K;

theorem Th11:
  n < 2 implies for p be Element of Permutations n holds p is even & p=idseq n
proof
  assume
A1: n<2;
  let p be Element of Permutations n;
  reconsider P=p as Permutation of Seg n by MATRIX_1:def 12;
  now
    per cases by A1,NAT_1:23;
    suppose
A2:   n=0;
    then
A3:   Seg n={};
A4:   len Permutations(n)=n by MATRIX_1:9;
      P={} by A2;
      hence thesis by A4,A3,MATRIX_1:16,RELAT_1:55;
    end;
    suppose
A5:   n=1;
A6:   len Permutations(n)=n by MATRIX_1:9;
      P=id Seg n by A5,MATRIX_1:10,TARSKI:def 1;
      hence thesis by A6,MATRIX_1:16;
    end;
  end;
  hence thesis;
end;
