
theorem Th11:
  for X be RealNormSpace for seq,seq1 be sequence of X holds seq
is convergent & (ex k be Nat st seq=seq1 ^\k) implies lim seq1 =lim
  seq
proof
  let X be RealNormSpace;
  let seq,seq1 be sequence of X;
  assume that
A1: seq is convergent and
A2: ex k be Nat st seq=seq1 ^\k;
  consider k be Nat such that
A3: seq=seq1 ^\k by A2;
A4: now
    let p be Real;
    assume 0<p;
    then consider n1 be Nat such that
A5: for m be Nat st n1<=m holds ||.seq.m-(lim seq).||<p by A1,
NORMSP_1:def 7;
    take n=n1+k;
    let m be Nat;
    assume
A6: n<=m;
    then consider l be Nat such that
A7: m=n1+k+l by NAT_1:10;
    reconsider l as Nat;
    m-k=n1+l+k+-k by A7;
    then reconsider m1=m-k as Nat;
    now
      assume not n1<=m1;
      then m1+k<n1+k by XREAL_1:6;
      hence contradiction by A6;
    end;
    then m1+k=m & ||.seq.m1-(lim seq) .||<p by A5;
    hence ||.seq1.m-(lim seq).||<p by A3,NAT_1:def 3;
  end;
  seq1 is convergent by A1,A2,Th10;
  hence thesis by A4,NORMSP_1:def 7;
end;
