reserve x,y for set,
  i,j,k,l,m,n for Nat,
  K for Field,
  N for without_zero finite Subset of NAT,
  a,b for Element of K,
  A,B,B1,B2,X,X1,X2 for (Matrix of K),
  A9 for (Matrix of m,n,K),
  B9 for (Matrix of m,k,K);

theorem Th11:
  for N st N c= dom A & for i st i in dom A \ N holds Line(A,i) =
  width A |-> 0.K holds the_rank_of A=the_rank_of Segm(A,N,Seg width A)
proof
  let N such that
A1: N c= dom A and
A2: for i st i in (dom A) \ N holds Line(A,i) = width A |-> 0.K;
  set w=width A;
  set l=len A;
  reconsider A9=A as Matrix of len A,width A,K by MATRIX_0:51;
  set S=Segm(A9,N,Seg width A9);
  consider U be finite Subset of w-VectSp_over K such that
A3: U is linearly-independent and
A4: U c= lines A9 and
A5: card U = the_rank_of A9 by MATRIX13:123;
A6: U c= lines S
  proof
    let x be object such that
A7: x in U;
    consider Ni be Nat such that
A8: Ni in Seg l and
A9: x = Line(A9,Ni) by A4,A7,MATRIX13:103;
A10: dom A=Seg l by FINSEQ_1:def 3;
A11: Ni in N
    proof
      assume not Ni in N;
      then Ni in dom A\N by A8,A10,XBOOLE_0:def 5;
      then x = w |-> 0.K by A2,A9
        .= 0.(w-VectSp_over K) by MATRIX13:102;
      hence thesis by A3,A7,VECTSP_7:2;
    end;
    rng Sgm N=N by FINSEQ_1:def 14;
    then consider i be object such that
A12: i in dom Sgm N and
A13: Sgm N.i=Ni by A11,FUNCT_1:def 3;
    reconsider i as Element of NAT by A12;
A14: dom Sgm N=Seg card N by FINSEQ_3:40;
    then Line(S,i) = x by A9,A12,A13,MATRIX13:48;
    hence thesis by A12,A14,MATRIX13:103;
  end;
A15: now
    let W be finite Subset of w-VectSp_over K such that
A16: W is linearly-independent and
A17: W c= lines S;
    dom A=Seg l by FINSEQ_1:def 3;
    then lines S c= lines A9 by A1,MATRIX13:118;
    then W c= lines A9 by A17;
    hence card W <= the_rank_of A9 by A16,MATRIX13:123;
  end;
  w=card Seg w by FINSEQ_1:57;
  hence thesis by A3,A5,A6,A15,MATRIX13:123;
end;
