
theorem Th5:
for X1,X2 be non empty set, S1 be SigmaField of X1, S2 be SigmaField of X2,
M1 be sigma_Measure of S1, M2 be sigma_Measure of S2,
A be Element of S1, B be Element of S2 holds
 product_Measure(M1,M2).([:A,B:]) = M1.A * M2.B
proof
   let X1,X2 be non empty set, S1 be SigmaField of X1, S2 be SigmaField of X2,
       M1 be sigma_Measure of S1, M2 be sigma_Measure of S2,
       A be Element of S1, B be Element of S2;
   set S = measurable_rectangles(S1,S2);
   set P = product-pre-Measure(M1,M2);
   set m = product_Measure(M1,M2);
A1:DisUnion S = Field_generated_by S by SRINGS_3:22;
   [:A,B:] in the set of all [:A,B:]
       where A is Element of S1, B is Element of S2; then
A2:[:A,B:] in S by MEASUR10:def 5; then
   reconsider F = <* [:A,B:] *> as disjoint_valued FinSequence of S
      by FINSEQ_1:74;
A3:S c= DisUnion S by SRINGS_3:12;
   consider SumPF be sequence of ExtREAL such that
A4: Sum(P*F) = SumPF.(len(P*F)) & SumPF.0 = 0. &
    (for n be Nat st n < len(P*F) holds
      SumPF.(n+1) = SumPF.n + (P*F).(n+1)) by EXTREAL1:def 2;
A5:len F = 1 by FINSEQ_1:39; then
A6:1 in dom F by FINSEQ_3:25;
   len(P*F) = 1 by A5,FINSEQ_3:120; then
   Sum(P*F) = SumPF.0 + (P*F).(0+1) by A4; then
   Sum(P*F) = (P*F).1 by A4,XXREAL_3:4; then
   Sum(P*F) = P.(F.1) by A6,FUNCT_1:13; then
   Sum(P*F) = P.([:A,B:]); then
A7:Sum(P*F) = M1.A * M2.B by MEASUR10:22;
   rng <* [:A,B:] *> = { [:A,B:] } by FINSEQ_1:39; then
   union rng <* [:A,B:] *> = [:A,B:] by ZFMISC_1:25; then
   [:A,B:] = Union <* [:A,B:] *> by CARD_3:def 4;
   hence m.([:A,B:]) = M1.A * M2.B by A1,A2,A3,A7,MEASURE9:def 8;
end;
