reserve n,i,j,k,l for Nat;
reserve D for non empty set;
reserve c,d for Element of D;
reserve p,q,q9,r for FinSequence of D;
reserve RAS for MidSp-like non empty ReperAlgebraStr over n+2;
reserve a,b,d,pii,p9i for Point of RAS;
reserve p,q for Tuple of (n+1),RAS;
reserve m for Nat of n;

theorem Th11:
  RAS is_semi_additive_in m implies for a,d,p,q st q = (p+*(m,d))
  holds *'(a,(p+*(m,a@d))) = a@*'(a,q)
proof
  assume
A1: RAS is_semi_additive_in m;
  let a,d,p,q;
  set qq = (q+*(m,a@d));
  assume
A2: q = (p+*(m,d));
A3: qq = (p+*(m,a@d))
  proof
    set pp = (p+*(m,a@d));
    for k being Nat of n holds qq.k = pp.k
    proof
      let k be Nat of n;
      now
        per cases;
        suppose
A4:       k = m;
          pp.m = a@d by Th10;
          hence thesis by A4,Th10;
        end;
        suppose
A5:       k <> m;
          hence qq.k = q.k by FUNCT_7:32
            .= p.k by A2,A5,FUNCT_7:32
            .= pp.k by A5,FUNCT_7:32;
        end;
      end;
      hence thesis;
    end;
    hence thesis by Th9;
  end;
  q.m = d by A2,Th10;
  hence thesis by A1,A3;
end;
