reserve T, T1 for non empty TopSpace;
reserve F,G,H for Subset-Family of T,
  A,B,C,D for Subset of T,
  O,U for open Subset of T,
  p,q for Point of T,
  x,y,X for set;

theorem Th11:
  for F st F is discrete holds F is locally_finite
proof
  let F;
  assume
A1: F is discrete;
  for p ex A st p in A & A is open & { D: D in F & D meets A} is finite
  proof
    let p;
    consider U such that
A2: p in U and
A3: for A,B st A in F & B in F holds U meets A & U meets B implies A=B
    by A1;
    set SF={ D: D in F & D meets U };
    take O=U;
    SF<>{} implies ex A st SF={A}
    proof
      assume SF<>{};
      then consider a being object such that
A4:   a in SF by XBOOLE_0:def 1;
      consider D such that
A5:   a=D and
A6:   D in F & D meets O by A4;
      now
        let b be object;
        assume b in SF;
        then ex C st b=C & C in F & C meets O;
        then b=D by A3,A6;
        hence b in {D} by TARSKI:def 1;
      end;
      then
A7:   SF c= {D};
      {D} c=SF by A4,A5,ZFMISC_1:31;
      then SF={D} by A7,XBOOLE_0:def 10;
      hence thesis;
    end;
    hence thesis by A2;
  end;
  hence thesis;
end;
