reserve i, k, m, n for Nat,
  r, s for Real,
  rn for Real,
  x, y , z, X for set,
  T, T1, T2 for non empty TopSpace,
  p, q for Point of T,
  A, B, C for Subset of T,
  A9 for non empty Subset of T,
  pq for Element of [:the carrier of T,the carrier of T:],
  pq9 for Point of [:T,T:],
  pmet,pmet1 for Function of [:the carrier of T,the carrier of T:],REAL,
  pmet9,pmet19 for RealMap of [:T,T:] ,
  f,f1 for RealMap of T,
  FS2 for Functional_Sequence of [:the carrier of T,the carrier of T:],REAL,
  seq for Real_Sequence;

theorem Th11:
  for FS2 st (for n ex pmet st FS2.n=pmet & pmet
  is_a_pseudometric_of the carrier of T) & for pq holds FS2#pq is summable for
  pmet st for pq holds pmet.pq=Sum(FS2#pq) holds pmet is_a_pseudometric_of the
  carrier of T
proof
  set cT=the carrier of T;
  let FS2 such that
A1: for n ex pmet st FS2.n=pmet & pmet is_a_pseudometric_of cT and
A2: for pq holds FS2#pq is summable;
  let pmet such that
A3: for pq holds pmet.pq=Sum(FS2#pq);
  now
    let a,b,c be Point of T;
    thus pmet.(a,a)=0
    proof
      set aa=[a,a];
      set F=FS2#aa;
      now
        let n;
        consider pmet1 such that
A4:     FS2.n=pmet1 and
A5:     pmet1 is_a_pseudometric_of cT by A1;
        pmet1.(a,a)=0 by A5,NAGATA_1:28;
        hence F.n=0*F.n by A4,SEQFUNC:def 10;
      end;
      then
A6:   F=0(#)F by SEQ_1:9;
      F is summable by A2;
      then Sum(F)=0*Sum(F) by A6,SERIES_1:10;
      hence thesis by A3;
    end;
    thus pmet.(a,c)<=pmet.(a,b)+pmet.(c,b)
    proof
      set ab=[a,b],cb=[c,b],ac=[a,c];
      set Fac=FS2#ac;
      set Fab=FS2#ab;
      set Fcb=FS2#cb;
A7:   now
        let n;
A8:     FS2.n.ac= Fac.n & FS2.n.ab=Fab.n by SEQFUNC:def 10;
        consider pmet1 such that
A9:     FS2.n=pmet1 and
A10:    pmet1 is_a_pseudometric_of cT by A1;
A11:    0<=pmet1.(a,c) by A10,NAGATA_1:29;
        pmet1.(a,c)<=pmet1.(a,b)+pmet1.(c,b) by A10,NAGATA_1:28;
        then Fac.n<=(Fab.n+Fcb.n) by A9,A8,SEQFUNC:def 10;
        hence 0<=Fac.n & Fac.n<=(Fab+Fcb).n
                 by A9,A11,SEQFUNC:def 10,SEQ_1:7;
      end;
A12:  Fab is summable & Fcb is summable by A2;
      then Fab+Fcb is summable by SERIES_1:7;
      then
A13:  Sum(Fac)<=Sum(Fab+Fcb) by A7,SERIES_1:20;
A14:  Sum(Fab)=pmet.ab & Sum(Fcb)=pmet.cb by A3;
      Sum(Fab+Fcb)=Sum(Fab)+Sum(Fcb) by A12,SERIES_1:7;
      hence thesis by A3,A13,A14;
    end;
  end;
  hence thesis by NAGATA_1:28;
end;
