reserve X,X1 for set,
  r,s for Real,
  z for Complex,
  RNS for RealNormSpace,
  CNS, CNS1,CNS2 for ComplexNormSpace;

theorem Th11:
  for f be PartFunc of CNS,RNS st f is_uniformly_continuous_on X
  holds r(#)f is_uniformly_continuous_on X
proof
  let f be PartFunc of CNS,RNS;
  assume
A1: f is_uniformly_continuous_on X;
  then X c= dom f;
  hence
A2: X c= dom (r(#)f) by VFUNCT_1:def 4;
  now
    per cases;
    suppose
A3:   r=0;
      let p be Real;
      assume
A4:   0<p;
      then consider s such that
A5:   0<s and
      for x1,x2 be Point of CNS st x1 in X & x2 in X & ||.x1-x2.||<s holds
      ||.f/.x1-f/.x2.||<p by A1;
      take s;
      thus 0<s by A5;
      let x1,x2 be Point of CNS;
      assume that
A6:   x1 in X and
A7:   x2 in X and
      ||.x1-x2.||<s;
      ||.(r(#)f)/.x1-(r(#)f)/.x2.|| = ||.r*(f/.x1)-(r(#)f)/.x2.|| by A2,A6,
VFUNCT_1:def 4
        .= ||.0.RNS -(r(#)f)/.x2.|| by A3,RLVECT_1:10
        .= ||.0.RNS - r*(f/.x2).|| by A2,A7,VFUNCT_1:def 4
        .= ||.0.RNS - 0.RNS.|| by A3,RLVECT_1:10
        .= ||.0.RNS .|| by RLVECT_1:13
        .= 0 by NORMSP_0:def 6;
      hence ||.(r(#)f)/.x1-(r(#)f)/.x2.|| <p by A4;
    end;
    suppose
A8:   r<>0;
      let p be Real;
A9:   0<|.r.| by A8,COMPLEX1:47;
      assume 0<p;
      then 0 < p/|.r.| by A9;
      then consider s such that
A10:  0<s and
A11:  for x1,x2 be Point of CNS st x1 in X & x2 in X & ||.x1-x2.||<s
      holds ||.f/.x1-f/.x2.||<p/|.r.| by A1;
      take s;
      thus 0<s by A10;
      let x1,x2 be Point of CNS;
      assume that
A12:  x1 in X and
A13:  x2 in X and
A14:  ||.x1-x2.||<s;
A15:  ||.(r(#)f)/.x1-(r(#)f)/.x2.|| = ||.r*(f/.x1)-(r(#)f)/.x2.|| by A2,A12,
VFUNCT_1:def 4
        .= ||.r*(f/.x1) - r*(f/.x2).|| by A2,A13,VFUNCT_1:def 4
        .= ||.r*(f/.x1 - f/.x2).|| by RLVECT_1:34
        .= |.r.|*||.f/.x1 - f/.x2.|| by NORMSP_1:def 1;
      |.r.|*||.f/.x1-f/.x2.||<p/|.r.|*|.r.| by A9,A11,A12,A13,A14,XREAL_1:68;
      hence ||.(r(#)f)/.x1-(r(#)f)/.x2.|| < p by A9,A15,XCMPLX_1:87;
    end;
  end;
  hence thesis;
end;
