
theorem Th24:
  for A, B being finite Ordinal-Sequence holds Sum^ (A^B) = Sum^ A +^ Sum^ B
proof
  defpred P[Nat] means for A, B being finite Ordinal-Sequence
    st dom B = $1 holds Sum^ (A^B) = Sum^ A +^ Sum^ B;
  A1: P[0]
  proof
    let A, B be finite Ordinal-Sequence;
    assume dom B = 0;
    then B = {};
    hence Sum^(A^B) = Sum^ A +^ Sum^ B by ORDINAL2:27, ORDINAL5:52;
  end;
  A2: for n being Nat st P[n] holds P[n+1]
  proof
    let n be Nat;
    assume A3: P[n];
    let A, B be finite Ordinal-Sequence;
    assume A4: dom B = n+1;
    then B <> {};
    then consider C being XFinSequence, a being object such that
      A5: B = C ^ <% a %> by AFINSQ_1:40;
    consider b being Ordinal such that
      A6: rng B c= b by ORDINAL2:def 4;
    rng C c= rng B by A5, AFINSQ_1:24;
    then reconsider C as finite Ordinal-Sequence
      by A6, XBOOLE_1:1, ORDINAL2:def 4;
    rng <% a %> c= rng B by A5, AFINSQ_1:25;
    then {a} c= rng B by AFINSQ_1:33;
    then a in rng B by ZFMISC_1:31;
    then reconsider a as Ordinal;
    A7: dom C + 1 = len C + len <% a %> by AFINSQ_1:34
      .= n+1 by A4, A5, AFINSQ_1:17;
    thus Sum^ (A^B) = Sum^ ((A^C)^<%a%>) by A5, AFINSQ_1:27
      .= Sum^ (A^C) +^ a by ORDINAL5:54
      .= Sum^ A +^ Sum^ C +^ a by A3, A7
      .= Sum^ A +^ (Sum^ C +^ a) by ORDINAL3:30
      .= Sum^ A +^ Sum^ B by A5, ORDINAL5:54;
  end;
  A8: for n being Nat holds P[n] from NAT_1:sch 2(A1,A2);
  let A, B be finite Ordinal-Sequence;
  dom B is Nat;
  hence thesis by A8;
end;
