reserve x,x0,x1,x2,y,y0,y1,y2,r,r1,s,p,p1 for Real;
reserve z,z0 for Element of REAL 2;
reserve n,m,k for Element of NAT;
reserve Z for Subset of REAL 2;
reserve s1 for Real_Sequence;
reserve f,f1,f2 for PartFunc of REAL 2,REAL;
reserve R,R1,R2 for RestFunc;
reserve L,L1,L2 for LinearFunc;

theorem Th11:
  z = <*x0,y0*> & f is_partial_differentiable_in z,1 implies (r =
  partdiff(f,z,1) iff
  ex x0,y0 being Real st z = <*x0,y0*> & ex N being
Neighbourhood of x0 st N c= dom SVF1(1,f,z) & ex L,R st r = L.1 & for x st x in
  N holds SVF1(1,f,z).x - SVF1(1,f,z).x0 = L.(x-x0) + R.(x-x0))
proof
  assume that
A1: z = <*x0,y0*> and
A2: f is_partial_differentiable_in z,1;
  hereby
    assume r = partdiff(f,z,1);
    then r = diff(SVF1(1,f,z),x0) by A1,Th1;
    hence
    ex x0,y0 being Real st z = <*x0,y0*> &
    ex N being Neighbourhood of x0
st N c= dom SVF1(1,f,z) & ex L,R st r = L.1 & for x st x in N holds SVF1(1,f,z)
    .x - SVF1(1,f,z).x0 = L.(x-x0) + R.(x-x0) by A1,A2,Lm1;
  end;
  given x1,y1 being Real such that
A3: z = <*x1,y1*> & ex N being Neighbourhood of x1 st N c= dom SVF1(1,f,
z) & ex L,R st r = L.1 & for x st x in N holds SVF1(1,f,z).x - SVF1(1,f,z).x1 =
  L.(x-x1 ) + R.(x- x1);
  r = diff(SVF1(1,f,z),x0) by A1,A2,A3,Lm1;
  hence thesis by A1,Th1;
end;
