
theorem Th11:
  for I being non empty set for A being PLS-yielding ManySortedSet
  of I for X,Y being Subset of Segre_Product A st X is non trivial
  closed_under_lines strong & Y is non trivial closed_under_lines strong & X,Y
  are_joinable for X1,Y1 being Segre-like non trivial-yielding ManySortedSubset
of Carrier A st X = product X1 & Y = product Y1 holds indx(X1) = indx(Y1) &
 for i being object st i <> indx(X1) holds X1.i = Y1.i
proof
  let I be non empty set;
  let A be PLS-yielding ManySortedSet of I;
  let X,Y be Subset of Segre_Product A;
  assume that
A1: X is non trivial closed_under_lines strong and
A2: Y is non trivial closed_under_lines strong and
A3: X,Y are_joinable;
  set B=bool the carrier of Segre_Product A;
  consider f being FinSequence of B such that
A4: X = f.1 and
A5: Y = f.(len f) and
A6: for W being Subset of Segre_Product A st W in rng f holds W is
  closed_under_lines strong and
A7: for i being Element of NAT st 1 <= i & i < len f holds 2 c= card((f
  . i) /\ (f.(i+1))) by A3;
  len f in dom f by A2,A5,FUNCT_1:def 2;
  then
A8: 1 <= len f by FINSEQ_3:25;
  consider B0 being Segre-like non trivial-yielding ManySortedSubset of
  Carrier A such that
A9: X = product B0 and
  for C being Subset of A.indx(B0) st C=B0.indx(B0) holds C is strong
  closed_under_lines by A1,PENCIL_1:29;
  let X1,Y1 be Segre-like non trivial-yielding ManySortedSubset of Carrier A
  such that
A10: X = product X1 and
A11: Y = product Y1;
  defpred P[Element of NAT] means for H being Segre-like non trivial-yielding
  ManySortedSubset of Carrier A st f.$1 = product H holds indx(X1) = indx(H) &
  for i being object st i <> indx(X1) holds X1.i = H.i;
A12: B0=X1 by A10,A9,PUA2MSS1:2;
A13: for j being Element of NAT st 1 <= j & j < len f holds P[j] implies P[j
  +1]
  proof
    let j be Element of NAT;
    assume that
A14: 1 <= j and
A15: j < len f;
    j in dom f by A14,A15,FINSEQ_3:25;
    then
A16: f.j in rng f by FUNCT_1:3;
A17: 1 <= j+1 by NAT_1:11;
    j+1 <= len f by A15,NAT_1:13;
    then j+1 in dom f by A17,FINSEQ_3:25;
    then f.(j+1) in rng f by FUNCT_1:3;
    then reconsider
    fj = f.j, fj1 = f.(j+1) as Subset of Segre_Product A by A16;
A18: card (fj /\ fj1) c= card fj by CARD_1:11,XBOOLE_1:17;
A19: 2 c= card (fj /\ fj1) by A7,A14,A15;
    then 2 c= card fj by A18;
    then fj is non trivial closed_under_lines strong by A6,A16,PENCIL_1:4;
    then consider B1 being Segre-like non trivial-yielding ManySortedSubset of
    Carrier A such that
A20: fj = product B1 and
    for C being Subset of A.indx(B1) st C=B1.indx(B1) holds C is strong
    closed_under_lines by PENCIL_1:29;
    assume
A21: P[j];
    then
A22: indx(B0) = indx(B1) by A12,A20;
    now
      let H be Segre-like non trivial-yielding ManySortedSubset of Carrier A;
      assume
A23:  f.(j+1) = product H;
      hence indx(X1) = indx(H) by A12,A20,A22,A19,PENCIL_1:26;
      thus for i being object st i <> indx(X1) holds X1.i = H.i
      proof
        let i be object;
        assume
A24:    i <> indx(X1);
        then
A25:    i <> indx(B1) by A21,A20;
        thus X1.i = B1.i by A21,A20,A24
          .= H.i by A20,A19,A23,A25,PENCIL_1:26;
      end;
    end;
    hence thesis;
  end;
A26: P[1] by A10,A4,PUA2MSS1:2;
  for i being Element of NAT st 1 <= i & i <= len f holds P[i] from
  INT_1:sch 7(A26,A13);
  hence thesis by A11,A5,A8;
end;
