reserve x for set;
reserve a, b, c, d, e for Real;
reserve m, n, m1, m2 for Nat;
reserve k, l for Integer;
reserve p for Rational;

theorem Th11:
  n>=1 & a>=0 & b>=0 or n is odd implies n-root (a*b) = n-root a * n-root b
proof
  assume
A1: n>=1 & a>=0 & b>=0 or n is odd;
A2: now
    let a,b,n;
    assume that
A3: n>=1 and
A4: a>=0 and
A5: b>=0;
    thus n-root (a*b) = n -Root (a*b) by A3,A4,A5,Def1
      .= n -Root a * n -Root b by A3,A4,A5,PREPOWER:22
      .= n-root a * n -Root b by A3,A4,Def1
      .= n-root a * n-root b by A3,A5,Def1;
  end;
 now
    assume
A6: n is odd;
    then
A7: n>=1 by ABIAN:12;
 now per cases;
      suppose
    a>=0 & b>=0;
        hence thesis by A2,A7;
      end;
      suppose
A8:    a<0 & b<0;
        thus
        then n-root (a*b) = n -Root ((-a)*(-b)) by A7,Def1
          .= (-(-n -Root (-a))) * n -Root (-b) by A7,A8,PREPOWER:22
          .= (-(n-root a)) * (-(-n -Root (-b))) by A6,A8,Def1
          .= (-(n-root a)) * (-(n-root b)) by A6,A8,Def1
          .= n-root a * n-root b;
      end;
      suppose
A9:    a>=0 & b<0;
        thus
        n-root (a*b) = -n-root (-a*b) by A6,Th10
          .= -n-root (a*(-b))
          .= -(n-root a * n-root (-b)) by A2,A7,A9
          .= n-root a * (-n-root (-b))
          .= n-root a * n-root b by A6,Th10;
      end;
      suppose
A10:    a<0 & b>=0;
        thus
        n-root (a*b) = -n-root (-a*b) by A6,Th10
          .= -n-root ((-a)*b)
          .= -(n-root (-a) * n-root b) by A2,A7,A10
          .= (-n-root (-a)) * n-root b
          .= n-root a * n-root b by A6,Th10;
      end;
    end;
    hence thesis;
  end;
  hence thesis by A1,A2;
end;
