reserve Omega, Omega1, Omega2 for non empty set;
reserve Sigma for SigmaField of Omega;
reserve S1 for SigmaField of Omega1;
reserve S2 for SigmaField of Omega2;
reserve F for random_variable of S1,S2;

theorem
  for F be random_variable of S1,S2 holds
  {x where x is Subset of Omega1 : ex y be Element of S2 st x =F"y } c= S1 &
  {x where x is Subset of Omega1 : ex y be Element of S2 st x =F"y }
  is SigmaField of Omega1
  proof
    let F be random_variable of S1,S2;
    set S = {x where x is Subset of Omega1 :
      ex y be Element of S2 st x = F"y };
    for x be object st x in S holds x in S1
    proof
      let z be object;
      assume z in S;
      then consider x be Subset of Omega1 such that
      A1: z= x & ex y be Element of S2 st x =F"y;
      thus z in S1 by A1,FINANCE1:def 5;
    end;
    hence A2: S c= S1;
    {} is Element of S2 by PROB_1:22; then
    A3:F"{} in S;
    A4: for A be Subset of Omega1 st A in S holds A` in S
    proof
      let A be Subset of Omega1;
      assume A in S; then
      consider x be Subset of Omega1 such that
      A5: A= x & ex y be Element of S2 st x =F"y;
      consider y be Element of S2 such that
      A6: x = F"y by A5;
      A7: y` in S2 by PROB_1:def 1;
      F"(y`) = F"Omega2 \ F"y by FUNCT_1:69
      .= A` by A5,A6,FUNCT_2:40;
      hence A` in S by A7;
    end;
    for A1 being SetSequence of Omega1
    st rng A1 c= S holds Intersection A1 in S
    proof
      let A1 be SetSequence of Omega1;
      assume A8: rng A1 c= S;
      defpred Q[set,set] means A1.$1 = F"$2 & $2 in S2;
      A9: for n be Element of NAT
      ex Bn be Element of bool Omega2 st Q[n,Bn]
      proof
        let n be Element of NAT;
        A1.n in rng A1 by FUNCT_2:112; then
        A1.n in S by A8; then
        consider x be Subset of Omega1 such that
        A10: A1.n= x & ex y be Element of S2 st x =F"y;
        thus thesis by A10;
      end;
      consider B being Function of NAT,bool Omega2 such that
      A11: for x being Element of NAT
      holds Q[x,B.x] from FUNCT_2:sch 3(A9);
      reconsider B as SetSequence of bool Omega2;
      now let y be object;
        assume y in rng B; then
        consider x be object such that
        A12: x in NAT & B.x = y by FUNCT_2:11;
        reconsider x as Element of NAT by A12;
        thus y in S2 by A12,A11;
      end; then
      rng B c= S2; then
      reconsider B1 = Intersection B as Element of S2 by PROB_1:15;
      F"(B1) = Intersection A1 by Th3,A11;
      hence Intersection A1 in S;
    end;
    hence S is SigmaField of Omega1 by PROB_1:15,A3,A4,A2,XBOOLE_1:1;
  end;
