reserve x,y for set,
        r,s for Real,
        n for Nat,
        V for RealLinearSpace,
        v,u,w,p for VECTOR of V,
        A,B for Subset of V,
        Af for finite Subset of V,
        I for affinely-independent Subset of V,
        If for finite affinely-independent Subset of V,
        F for Subset-Family of V,
        L1,L2 for Linear_Combination of V;

theorem Th11:
  for L be Linear_Combination of A st L is convex & Sum L in Int A
    holds Carrier L = A
  proof
    let L be Linear_Combination of A such that
    A1: L is convex and
    A2: Sum L in Int A;
    reconsider C=Carrier L as non empty Subset of V by A1,CONVEX1:21;
    reconsider LC=L as Linear_Combination of C by RLVECT_2:def 6;
    LC in ConvexComb(V) by A1,CONVEX3:def 1;
    then Sum LC in {Sum M where M is Convex_Combination of C:
      M in ConvexComb(V)} by A1;
    then A3: Sum L in conv C by CONVEX3:5;
    A4: Carrier L c=A by RLVECT_2:def 6;
    assume Carrier L<>A;
    then Carrier L c<A by A4;
    hence contradiction by A2,A3,Def1;
  end;
