reserve n for Nat,
  a,b,c,d for Real,
  s for Real_Sequence;

theorem
  (a <> 1 & a <> 0 & for n holds s.n = (1/a)|^n) implies for n holds
  Partial_Sums(s).n = ((1/a)|^n-a)/(1-a)
proof
  assume that
A1: a<>1 and
A2: a <> 0;
  defpred X[Nat] means Partial_Sums(s).$1 = ((1/a)|^$1-a)/(1-a);
  assume
A3: for n holds s.n = (1/a)|^n;
A4: 1-a <> 0 by A1;
A5: for n st X[n] holds X[n+1]
  proof
    let n;
    assume Partial_Sums(s).n = ((1/a)|^n-a)/(1-a);
    hence Partial_Sums(s).(n+1) = ((1/a)|^n-a)/(1-a)+ s.(n+1) by SERIES_1:def 1
      .= ((1/a)|^n-a)/(1-a) + (1/a)|^(n+1) * 1 by A3
      .= ((1/a)|^n-a)/(1-a)+(1/a)|^(n+1)*((1-a)/(1-a)) by A4,XCMPLX_1:60
      .= ((1/a)|^n-a)/(1-a)+((1/a)|^(n+1)*(1-a))/(1-a) by XCMPLX_1:74
      .= ((1/a)|^n-a + ((1/a)|^(n+1)*1-(1/a)|^(n+1)*a))/(1-a) by XCMPLX_1:62
      .= ((1/a)|^n-a + (1/a)|^(n+1)-((1/a)|^(n+1))*a)/(1-a)
      .= ((1/a)|^n-a + (1/a)|^(n+1)-((1/a)|^n*(1/a))*a)/(1-a) by NEWTON:6
      .= ((1/a)|^n-a + (1/a)|^(n+1)-(1/a)|^n*(1/a*a))/(1-a)
      .= ((1/a)|^n-a + (1/a)|^(n+1)-(1/a)|^n*1)/(1-a) by A2,XCMPLX_1:106
      .= ((1/a)|^(n+1)-a)/(1-a);
  end;
  Partial_Sums(s).0 = s.0 by SERIES_1:def 1
    .= (1/a)|^0 by A3
    .= 1 by NEWTON:4
    .= (1-a)/(1-a) by A4,XCMPLX_1:60
    .= ((1/a)|^0-a)/(1-a) by NEWTON:4;
  then
A6: X[0];
  for n holds X[n] from NAT_1:sch 2(A6,A5);
  hence thesis;
end;
