reserve V for Universe,
  a,b,x,y,z,x9,y9 for Element of V,
  X for Subclass of V,
  o,p,q,r,s,t,u,a1,a2,a3,A,B,C,D for set,
  K,L,M for Ordinal,
  n for Element of omega,
  fs for finite Subset of omega,
  e,g,h for Function,
  E for non empty set,
  f for Function of VAR,E,
  k,k1 for Element of NAT,
  v1,v2,v3 for Element of VAR,
  H,H9 for ZF-formula;

theorem Th11:
  X is closed_wrt_A1-A7 & n in fs & a in X & b in X & b c= Funcs(
  fs,a) implies {x: x in Funcs(fs\{n},a) & ex u st {[n,u]} \/ x in b} in X
proof
  assume that
A1: X is closed_wrt_A1-A7 and
A2: n in fs and
A3: a in X and
A4: b in X and
A5: b c= Funcs(fs,a);
A6: Funcs({n},a) in X by A1,A3,Th9;
  then reconsider F=Funcs({n},a) as Element of V;
  set T={[n,x]: x in a};
A7: T=union F
  proof
    thus T c= union F
    proof
      let q be object;
      assume q in T;
      then consider x such that
A8:   q=[n,x] and
A9:   x in a;
      reconsider g={[n,x]} as Function;
      rng g={x} by RELAT_1:9;
      then dom g={n} & rng g c= a by A9,RELAT_1:9,ZFMISC_1:31;
      then
A10:  g in F by FUNCT_2:def 2;
      q in g by A8,TARSKI:def 1;
      hence thesis by A10,TARSKI:def 4;
    end;
    let q be object;
    assume q in union F;
    then consider A such that
A11: q in A and
A12: A in F by TARSKI:def 4;
    consider g such that
A13: A=g and
A14: dom g={n} and
A15: rng g c= a by A12,FUNCT_2:def 2;
    n in dom g by A14,TARSKI:def 1;
    then
A16: g.n in rng g by FUNCT_1:def 3;
    then reconsider o=g.n as Element of V by A3,A15,Th1;
    q in {[n,g.n]} by A11,A13,A14,GRFUNC_1:7;
    then q=[n,o] by TARSKI:def 1;
    hence thesis by A15,A16;
  end;
  then T in X by A1,A6,Th2;
  then
A17: {T} in X by A1,Th2;
  then reconsider t={T} as Element of V;
  set Y={x: x in Funcs(fs\{n},a) & ex u st {[n,u]} \/ x in b};
  set Z={y\z: y in b & z in t};
A18: Z=Y
  proof
    thus Z c= Y
    proof
      let q be object;
      assume q in Z;
      then consider y,z such that
A19:  q=y\z and
A20:  y in b and
A21:  z in t;
A22:  q=y\T by A19,A21,TARSKI:def 1;
      consider g such that
A23:  y=g and
A24:  dom g=fs and
A25:  rng g c= a by A5,A20,FUNCT_2:def 2;
      set h=g|(fs\{n});
A26:  dom h=fs /\ (fs\{n}) by A24,RELAT_1:61
        .=fs /\ fs \ fs /\ {n} by XBOOLE_1:50
        .=fs\{n} by XBOOLE_1:47;
A27:  h=g\T
      proof
       let r,s be object;
        thus [r,s] in h implies [r,s] in g\T
        proof
          assume
A28:      [r,s] in h;
          r in fs\{n} by A26,A28,FUNCT_1:1;
          then not r in {n} by XBOOLE_0:def 5;
          then
A29:      r<>n by TARSKI:def 1;
A30:      not [r,s] in T
          proof
            assume [r,s] in T;
            then ex x st [r,s]=[n,x] & x in a;
            hence contradiction by A29,XTUPLE_0:1;
          end;
          [r,s] in g by A28,RELAT_1:def 11;
          hence thesis by A30,XBOOLE_0:def 5;
        end;
        assume
A31:    [r,s] in g\T;
A32:    s=g.r by A31,FUNCT_1:1;
A33:    r in dom g by A31,FUNCT_1:1;
        then
A34:    s in rng g by A32,FUNCT_1:def 3;
        n<>r
        proof
          reconsider a1=s as Element of V by A3,A25,A34,Th1;
          assume n=r;
          then [r,a1] in T by A25,A34;
          hence contradiction by A31,XBOOLE_0:def 5;
        end;
        then not r in {n} by TARSKI:def 1;
        then
A35:    r in fs\{n} by A24,A33,XBOOLE_0:def 5;
        then s=h.r by A32,FUNCT_1:49;
        hence thesis by A26,A35,FUNCT_1:1;
      end;
      rng h c= rng g by RELAT_1:70;
      then rng h c= a by A25;
      then
A36:  q in Funcs(fs\{n},a) by A22,A23,A26,A27,FUNCT_2:def 2;
      Funcs(fs\{n},a) in X by A1,A3,Th9;
      then reconsider a2=q as Element of V by A36,Th1;
      {[n,g.n]}=y/\T
      proof
        thus {[n,g.n]} c= y/\T
        proof
          let r,s be object;
A37:      g.n in rng g by A2,A24,FUNCT_1:def 3;
          then reconsider a1=g.n as Element of V by A3,A25,Th1;
A38:      [n,a1] in T by A25,A37;
          set p = [r,s];
          assume p in {[n,g.n]};
          then
A39:      p=[n,g.n] by TARSKI:def 1;
          then p in y by A2,A23,A24,FUNCT_1:1;
          hence thesis by A39,A38,XBOOLE_0:def 4;
        end;
        let p be object;
        assume
A40:    p in y/\T;
        then p in T by XBOOLE_0:def 4;
        then
A41:    ex x st p=[n,x] & x in a;
        p in y by A40,XBOOLE_0:def 4;
        then p=[n,g.n] by A23,A41,FUNCT_1:1;
        hence thesis by TARSKI:def 1;
      end;
      then {[n,g.n]} \/ (y\T) in b by A20,XBOOLE_1:51;
      then a2 in Y by A22,A36;
      hence thesis;
    end;
    reconsider z=T as Element of V by A7;
    let q be object;
    assume q in Y;
    then consider x such that
A42: q=x and
A43: x in Funcs(fs\{n},a) and
A44: ex u st {[n,u]} \/ x in b;
    consider u such that
A45: {[n,u]} \/ x in b by A44;
    reconsider y={[n,u]} \/ x as Element of V by A4,A45,Th1;
A46: x=y\z
    proof
      consider g such that
A47:  x=g and
A48:  dom g=fs\{n} and
      rng g c= a by A43,FUNCT_2:def 2;
      thus x c= y\z
      proof
        let p be object;
        assume
A49:    p in x;
        then consider a1,a2 being object such that
A50:    p=[a1,a2] by A47,RELAT_1:def 1;
        a1 in dom g by A47,A49,A50,FUNCT_1:1;
        then
A51:    not a1 in {n} by A48,XBOOLE_0:def 5;
A52:    not p in z
        proof
          assume p in z;
          then ex x9 st p=[n,x9] & x9 in a;
          then a1=n by A50,XTUPLE_0:1;
          hence contradiction by A51,TARSKI:def 1;
        end;
        p in y by A49,XBOOLE_0:def 3;
        hence thesis by A52,XBOOLE_0:def 5;
      end;
      thus y\z c= x
      proof
A53:    x misses z
        proof
          assume not thesis;
          then consider r being object such that
A54:      r in g and
A55:      r in z by A47,XBOOLE_0:3;
          consider a1,a2 being object such that
A56:      r=[a1,a2] by A54,RELAT_1:def 1;
          a1 in dom g by A54,A56,FUNCT_1:1;
          then
A57:      not a1 in {n} by A48,XBOOLE_0:def 5;
          not r in z
          proof
            assume r in z;
            then ex x9 st r=[n,x9] & x9 in a;
            then a1=n by A56,XTUPLE_0:1;
            hence contradiction by A57,TARSKI:def 1;
          end;
          hence contradiction by A55;
        end;
        {[n,u]} c= z
        proof
          consider g such that
A58:      {[n,u]} \/ x = g and
          dom g=fs and
A59:      rng g c= a by A5,A45,FUNCT_2:def 2;
          {[n,u]} c= g by A58,XBOOLE_1:7;
          then [n,u] in g by ZFMISC_1:31;
          then n in dom g & u=g.n by FUNCT_1:1;
          then
A60:      u in rng g by FUNCT_1:def 3;
          then reconsider a1=u as Element of V by A3,A59,Th1;
          assume not thesis;
          then
A61:      ex r being object st r in {[n,u]} & not r in z;
          [n,a1] in z by A59,A60;
          hence contradiction by A61,TARSKI:def 1;
        end;
        then {[n,u]}\z={} by XBOOLE_1:37;
        then
A62:    (x\z)\/({[n,u]}\z)=x by A53,XBOOLE_1:83;
        let p be object;
        assume p in y\z;
        hence thesis by A62,XBOOLE_1:42;
      end;
    end;
    z in t by TARSKI:def 1;
    hence thesis by A42,A45,A46;
  end;
  X is closed_wrt_A6 by A1;
  hence thesis by A4,A17,A18;
end;
