reserve x,y,y1,y2 for set;
reserve G for Group;
reserve a,b,c,d,g,h for Element of G;
reserve A,B,C,D for Subset of G;
reserve H,H1,H2,H3 for Subgroup of G;
reserve n for Nat;
reserve i for Integer;
reserve L for Subset of Subgroups G;
reserve N2 for normal Subgroup of G;

theorem
  for H being Subgroup of G holds H is normal Subgroup of G iff for A
  holds A * H = H * A
proof
  let H be Subgroup of G;
  thus H is normal Subgroup of G implies for A holds A * H = H * A
  proof
    assume
A1: H is normal Subgroup of G;
    let A;
    thus A * H c= H * A
    proof
      let x be object;
      assume x in A * H;
      then consider a,h such that
A2:   x = a * h and
A3:   a in A and
A4:   h in H by GROUP_2:94;
      x in a * H by A2,A4,GROUP_2:103;
      then x in H * a by A1,Th117;
      then ex g st x = g * a & g in H by GROUP_2:104;
      hence thesis by A3;
    end;
    let x be object;
    assume x in H * A;
    then consider h,a such that
A5: x = h * a & h in H and
A6: a in A by GROUP_2:95;
    x in H * a by A5,GROUP_2:104;
    then x in a * H by A1,Th117;
    then ex g st x = a * g & g in H by GROUP_2:103;
    hence thesis by A6;
  end;
  assume
A7: for A holds A * H = H * A;
  now
    let a;
    thus a * H = {a} * H .= H * {a} by A7
      .= H * a;
  end;
  hence thesis by Th117;
end;
