reserve a,b for Complex;
reserve V,X,Y for ComplexLinearSpace;
reserve u,u1,u2,v,v1,v2 for VECTOR of V;
reserve z,z1,z2 for Complex;
reserve V1,V2,V3 for Subset of V;
reserve W,W1,W2 for Subspace of V;
reserve x for set;
reserve w,w1,w2 for VECTOR of W;
reserve D for non empty set;
reserve d1 for Element of D;
reserve A for BinOp of D;
reserve M for Function of [:COMPLEX,D:],D;
reserve B,C for Coset of W;
reserve CNS for ComplexNormSpace;
reserve x, y, w, g, g1, g2 for Point of CNS;
reserve S, S1, S2 for sequence of CNS;
reserve n, m, m1, m2 for Nat;
reserve r for Real;

theorem
  S is convergent implies lim (z * S) = z * (lim S)
proof
  set g = lim S;
  set h = z * g;
  assume
A1: S is convergent;
A2: now
    assume
A3: z = 0;
    let r;
    assume 0 < r;
    then consider m1 such that
A4: for n st m1 <= n holds ||.(S.n) - g.|| < r by A1,Def16;
    take k = m1;
    let n;
    assume k <= n;
    then
A5: ||.(S.n) - g.|| < r by A4;
    ||.z * (S.n) - z * g.|| = ||.0c * (S.n) - 09(CNS).|| by A3,Th1
      .= ||.09(CNS) - 09(CNS).|| by Th1
      .= ||.09(CNS).|| by RLVECT_1:13
      .= 0;
    then ||.z * (S.n) - h.|| < r by A5,Th105;
    hence ||.(z * S).n - h.|| < r by Def14;
  end;
A6: now
    assume
A7: z <> 0c;
    then
A8: 0 < |.z.| by COMPLEX1:47;
    let r;
    assume 0 < r;
    then consider m1 such that
A9: for n st m1 <= n holds ||.(S.n) - g.|| < r/|.z.| by A1,A8,Def16;
    take k = m1;
    let n;
    assume k <= n;
    then
A10: ||.(S.n) - g.|| < r/|.z.| by A9;
A11: 0 <> |.z.| by A7,COMPLEX1:47;
A12: |.z.| * (r/|.z.|) = |.z.| * (|.z.|" * r) by XCMPLX_0:def 9
      .= |.z.| *|.z.|" * r
      .= 1 * r by A11,XCMPLX_0:def 7
      .= r;
    ||.(z * (S.n)) - (z * g).|| = ||.z * ((S.n) - g).|| by Th9
      .= |.z.| * ||.(S.n) - g.|| by Def13;
    then ||.(z *(S.n)) - h.|| < r by A8,A10,A12,XREAL_1:68;
    hence ||.(z * S).n - h.|| < r by Def14;
  end;
  z * S is convergent by A1,Th116;
  hence thesis by A2,A6,Def16;
end;
