reserve x,y,y1,y2 for set;
reserve G for Group;
reserve a,b,c,d,g,h for Element of G;
reserve A,B,C,D for Subset of G;
reserve H,H1,H2,H3 for Subgroup of G;
reserve n for Nat;
reserve i for Integer;
reserve L for Subset of Subgroups G;
reserve N2 for normal Subgroup of G;

theorem
  for H being strict Subgroup of G holds H is normal Subgroup of G iff
  for a holds H |^ a is Subgroup of H
proof
  let H be strict Subgroup of G;
  thus H is normal Subgroup of G implies for a holds H |^ a is Subgroup of H
  proof
    assume
A1: H is normal Subgroup of G;
    let a;
    H |^ a = the multMagma of H by A1,Def13;
    hence thesis by GROUP_2:54;
  end;
  assume
A2: for a holds H |^ a is Subgroup of H;
  now
    let a;
A3: H |^ a" * a = a"" * H * a" * a by Th59
      .= a"" * H * (a" * a) by GROUP_2:34
      .= a"" * H * 1_G by GROUP_1:def 5
      .= a"" * H by GROUP_2:37
      .= a * H;
    H |^ a" is Subgroup of H by A2;
    hence a * H c= H * a by A3,Th6;
  end;
  hence thesis by Th118;
end;
