reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;
reserve D for non vertical non horizontal non empty compact Subset of TOP-REAL
  2;
reserve f for clockwise_oriented non constant standard
  special_circular_sequence;
reserve p for Point of TOP-REAL 2;

theorem Th106:
  north_halfline p is non bounded
proof
  set Wp = north_halfline p;
  set p11 = p`1, p12 = p`2;
  assume Wp is bounded;
  then reconsider C = Wp as bounded Subset of Euclid 2 by Th5;
  consider r being Real such that
A1: 0 < r and
A2: for x,y being Point of Euclid 2 st x in C & y in C holds dist(x,y)
  <= r by TBSP_1:def 7;
  set EX2 = p`2+2*r, EX1 = p`1;
  reconsider p1 = p, EX = |[p`1, p`2+2*r]| as Point of Euclid 2 by EUCLID:67;
A3: |[p`1, EX2]|`1 = p`1;
  then
A4: p1 in Wp by TOPREAL1:def 10;
  0 + p`2 <= 2*r + p`2 by A1,XREAL_1:6;
  then |[p`1, EX2]|`2 >= p`2;
  then
A5: EX in Wp by A3,TOPREAL1:def 10;
  p = |[p11,p12]| by EUCLID:53;
  then dist (p1, EX) = sqrt ((p11 - EX1)^2 + (p12 - EX2)^2) by GOBOARD6:6
    .= sqrt ((EX2 - p12)^2 + 0)
    .= 2*r by A1,SQUARE_1:22;
  hence thesis by A1,A2,A5,A4,XREAL_1:155;
end;
