reserve x,x0, r,r1,r2 for Real,
      th for Real,

  rr for set,

  rseq for Real_Sequence;

theorem Th122:
  arcsec2 is_differentiable_on sec.:].PI/2,PI.[
proof
  set X = sec.:].PI/2,PI.[;
  set g1 = arcsec2|(sec.:].PI/2,PI.[);
  set f = sec|].PI/2,PI.];
  set g = f|].PI/2,PI.[;
A1: g = sec|].PI/2,PI.[ by RELAT_1:74,XXREAL_1:21;
A2: dom ((g|].PI/2,PI.[)") = rng (g|].PI/2,PI.[) by FUNCT_1:33
    .= rng(sec|].PI/2,PI.[) by A1,RELAT_1:72
    .= sec.:].PI/2,PI.[ by RELAT_1:115;
A3: (g|].PI/2,PI.[)" = (f|].PI/2,PI.[)" by RELAT_1:72
    .= arcsec2|(f.:].PI/2,PI.[) by RFUNCT_2:17
    .= arcsec2|(rng(f|].PI/2,PI.[)) by RELAT_1:115
    .= arcsec2|(rng (sec|].PI/2,PI.[)) by RELAT_1:74,XXREAL_1:21
    .= arcsec2|(sec.:].PI/2,PI.[) by RELAT_1:115;
A4: g is_differentiable_on ].PI/2,PI.[ by A1,Th6,FDIFF_2:16;
  now
A5: for x0 st x0 in ].PI/2,PI.[ holds sin.x0/(cos.x0)^2 > 0
    proof
      let x0;
      assume
A6:   x0 in ].PI/2,PI.[;
      ].PI/2,PI.[ c= ].PI/2,3/2*PI.[ by COMPTRIG:5,XXREAL_1:46;
      then
A7:   cos.x0 < 0 by A6,COMPTRIG:13;
      ].PI/2,PI.[ c= ].0,PI.[ by XXREAL_1:46;
      then sin.x0 > 0 by A6,COMPTRIG:7;
      hence thesis by A7;
    end;
    let x0 such that
A8: x0 in ].PI/2,PI.[;
    diff(g,x0) = (g`|].PI/2,PI.[).x0 by A4,A8,FDIFF_1:def 7
      .= ((sec|].PI/2,PI.[)`|].PI/2,PI.[).x0 by RELAT_1:74,XXREAL_1:21
      .= (sec`|].PI/2,PI.[).x0 by Th6,FDIFF_2:16
      .= diff(sec,x0) by A8,Th6,FDIFF_1:def 7
      .= sin.x0/(cos.x0)^2 by A8,Th6;
    hence diff(g,x0) > 0 by A8,A5;
  end;
  then
A9: g1 is_differentiable_on X by A2,A4,A3,Lm22,FDIFF_2:48;
A10: for x st x in X holds arcsec2|X is_differentiable_in x
  proof
    let x;
    assume x in X;
    then g1|X is_differentiable_in x by A9,FDIFF_1:def 6;
    hence thesis by RELAT_1:72;
  end;
  X c= dom arcsec2 by A2,A3,RELAT_1:60;
  hence thesis by A10,FDIFF_1:def 6;
end;
