reserve i,j,n,k,m for Nat,
     a,b,x,y,z for object,
     F,G for FinSequence-yielding FinSequence,
     f,g,p,q for FinSequence,
     X,Y for set,
     D for non empty set;
reserve
  B,A,M for BinOp of D,
  F,G for D* -valued FinSequence,
  f for FinSequence of D,
  d,d1,d2 for Element of D;
reserve
  F,G for non-empty non empty FinSequence of D*,
  f for non empty FinSequence of D;
reserve f,g for FinSequence of D,
        a,b,c for set,
        F,F1,F2 for finite set;

theorem Th124:
   for E be Enumeration of F, p be Permutation of dom E
   for s be FinSequence st s in doms(m,card F)
     holds s*p in doms(m,card F)
proof
  let E be Enumeration of F,p be Permutation of dom E;
  let s be FinSequence such that
A1: s in doms(m,card F);
  reconsider s1=s as Element of doms(m,card F) by A1;
  reconsider Ep=E*p as Enumeration of F by Th109;
A2: len s =card F =card E by Th121,A1,CARD_1:def 7;
  then
A3: dom E = dom s by FINSEQ_3:30;
A4: dom p = dom E = rng p by FUNCT_2:52,def 3;
  then
A5: dom (s*p) = dom s = Seg len s by A3,RELAT_1:27,FINSEQ_1:def 3;
  reconsider sp=s*p as FinSequence by A3;
A6: len sp = len s by A5,FINSEQ_3:29;
A7: rng s1 c= Seg m;
  rng sp = rng s by A3,A4,RELAT_1:28;
  then sp is FinSequence of Seg m by A7,FINSEQ_1:def 4;
  then sp in (Seg m)* by FINSEQ_1:def 11;
  hence thesis by A2,A6;
end;
